Selectively re-enabling Autorun on USB

[tannis00 0]

I don't know about the rest of you, but I liked the old autorun functionality. It was very useful for my portable apps USB drive. So... Thanks to several posts on this forum, I managed to put together the following AutoIt script. It doesn't look in the autorun.inf, but what it does do is to launch a specific program when a correctly named USB drive is inserted. Hope someone finds it useful...

expandcollapse popup

; Autorun
;
; This program is a workaround for Microsoft's annoying disabling of the autorun feature for USB drives (rather than fixing the real
; issue.
; Once started, autorun.exe will continuously monitor for insertion of USB drives. If the drive inserted matches the drive name
; specified ("Portable", unless a different name is specified on the command line), then a prescribed program will be launched 
; from that drive (asuite.exe unless a different name is specified on the command line).
;

Global $New, $myPgm, $MyDrive

Opt("TrayOnEventMode",1)
Opt("TrayMenuMode",1)   ; Default tray menu items (Script Paused/Exit) will not be shown.

TraySetClick(16)    ; Only secondary mouse button will show the tray menu.

$showitem = TrayCreateItem("Show parameters")
TrayItemSetOnEvent(-1,"ShowParms")

$exititem = TrayCreateItem("Exit")
TrayItemSetOnEvent(-1,"ExitScript")

TraySetState()

$wbemFlagReturnImmediately = 0x10
$wbemFlagForwardOnly = 0x20
$colItems = ""
$strComputer = "localhost"
$New = "[drive]:"
$MyDrive = "PORTABLES"
$myPgm = "\asuite.exe"

; Read command line parameters
If $cmdline[0] > "0" Then
    $MyDrive = $cmdLine[1]
EndIf
if $cmdLine[0] > "1" Then
    $myPgm = $cmdLine[2]
    if StringLeft($myPgm,1) <> "\" Then
        $myPgm = "\" & $myPgm
    EndIf
EndIf

; Setup drive insertion notification. This uses the Async method so that the exit menu command from the systray icon
; will work. Using the blocking form (ExecNotificationQuery) is easier on resources, but you can't exit until you insert
; a new USB drive.
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
$EventSink = ObjCreate("WbemScripting.SWbemSink")
ObjEvent($EventSink , "SINK_")

$objWMIservice.ExecNotificationQueryAsync ($EventSink, "SELECT * FROM __InstanceCreationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_DiskDrive'", Default, Default, Default)

While 1
WEnd

Exit

; Executed when a USB drive is inserted. If the drive name matches, then run the specified program from it.
Func SINK_OnObjectReady($objObject, $objAsyncContext)
    $obj = $objObject.TargetInstance
    If $obj.InterfaceType == "USB" Then
        $New = GetDriveLetterFromDisk($obj.Name)
        $Label = DriveGetLabel($New)
        If $Label == $MyDrive Then
            ShellExecute($New & $myPgm)
        EndIf
    EndIf
EndFunc

Func GetDriveLetterFromDisk($name)
    $ans = ""
    $name = StringReplace($name,"\","\\")
    $oq_part = $objWMIService.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & $name & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If IsObj($oq_part) Then
        For $obj_part In $oq_part
            $oq_disk = $objWMIService.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & $obj_part.DeviceID & """} WHERE AssocClass = Win32_LogicalDiskToPartition", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
            If IsObj($oq_disk) Then
                For $obj_disk in $oq_disk
                    $ans = $ans & $obj_disk.Name
                Next
            EndIf
        Next
    EndIf
    
    Return $ans
EndFunc

; Systray menu funtions follow
Func ShowParms()
    MsgBox(0, "Parameters", "Drive: " & $MyDrive & chr(13) & chr(10) & "Command: " & $New & $myPgm)
EndFunc

Func ExitScript()
    Exit
EndFunc
$objWMIService = ObjGet("winmgmts:\\" & $strComputer & "\root\CIMV2")
$EventSink = ObjCreate("WbemScripting.SWbemSink")
ObjEvent($EventSink , "SINK_")

$objWMIservice.ExecNotificationQueryAsync ($EventSink, "SELECT * FROM __InstanceCreationEvent WITHIN 1 WHERE TargetInstance ISA 'Win32_DiskDrive'", Default, Default, Default)

While 1
WEnd

Exit

Func SINK_OnObjectReady($objObject, $objAsyncContext)
    $obj = $objObject.TargetInstance
    If $obj.InterfaceType == "USB" Then
        $New = GetDriveLetterFromDisk($obj.Name)
        $Label = DriveGetLabel($New)
        If $Label == $MyDrive Then
            ShellExecute($New & $myPgm)
        EndIf
    EndIf
EndFunc

Func GetDriveLetterFromDisk($name)
    $ans = ""
    $name = StringReplace($name,"\","\\")
    $oq_part = $objWMIService.ExecQuery("ASSOCIATORS OF {Win32_DiskDrive.DeviceID=""" & $name & """} WHERE AssocClass = Win32_DiskDriveToDiskPartition", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
    If IsObj($oq_part) Then
        For $obj_part In $oq_part
            $oq_disk = $objWMIService.ExecQuery("ASSOCIATORS OF {Win32_DiskPartition.DeviceID=""" & $obj_part.DeviceID & """} WHERE AssocClass = Win32_LogicalDiskToPartition", "WQL", $wbemFlagReturnImmediately + $wbemFlagForwardOnly)
            If IsObj($oq_disk) Then
                For $obj_disk in $oq_disk
                    $ans = $ans & $obj_disk.Name
                Next
            EndIf
        Next
    EndIf
    
    Return $ans
EndFunc

; Systray menu funtions follow
Func ShowParms()
    MsgBox(0, "Parameters", "Drive: " & $MyDrive & chr(13) & chr(10) & "Command: " & $New & $myPgm)
EndFunc

Func ExitScript()
    Exit
EndFunc

[cengizhan 0]

Very nice. with a few modifications it can be turned into an autorun.inf remover.

[BrewManNH 1,121]

You duplicated the code in your posting, it's in there twice causing all sorts of trouble when trying to run it.

Another thing, put a small sleep in your While...Wend loop, your script is eating up about 50% CPU usage without at least a Sleep(10) in there.