Help on GUICtrlCreateInput

[Syed23]

hi All,

I have created a GUI where i will have created a Inputbox with the function GUICtrlCreateInput. In that input box i would like to have the default text like which will look like water message(like,shadow message). is that possible to do? how can we do that? do we need to use any DLL help ?

[Melba23]

Syed23,

You can thank rover for digging this up:

#include <GUIConstantsEX.au3>
#include <EditConstants.au3>
#include <WinAPI.au3>

$hGui = GUICreate("Test", 500, 300)

GUICtrlCreateLabel("Info", 10, 5)
Local $aInput[6][2] = [[0, "Name"],[0, "Address"],[0, "Home Phone"],[0, "Mobile Phone"],[0, "Date of birth"],[0, "Town"]]
For $i = 0 To UBound($aInput) - 1
    $aInput[$i][0] = GUICtrlCreateInput("", 10, (20 * ($i + 1)), 140, 20)
    GUICtrlSendMsg(-1, $EM_SETCUEBANNER, True, $aInput[$i][1])
Next

GUISetState()

While 1
    If GUIGetMsg() = $GUI_EVENT_CLOSE Then Exit
WEnd

;Does not work for edit controls with $ES_MULTILINE style.
;In XP, the banner disappears when the edit has focus (cursor in edit)
;In Vista/7 the banner can optionally still appear when the edit has focus (cursor in edit)
;(third parameter = True/False)

M23

[Syed23]

Thanks a lot Melba23! Thats perfect and what i wanted