Script pauses when I click tray icon

[Floppy]

Hello, please can you help me with this script?

Why when I click the tray icon, the script pauses?

expandcollapse popup

#include <GUIConstants.au3>
#include <Sound.au3>
 
Opt("TrayMenuMode", 3)
Opt("TrayAutoPause", 0)
 
$acc_job_sound = @DesktopDir&"\siren.mp3"
Global $t_ricev
Global $t_end
Global $job_sound
$job_sound = _SoundOpen($acc_job_sound)
 
TrayCreateItem("")
$t_chiudi = TrayCreateItem("Chiudi")
Start_alarm()
While 1
$tsg = TrayGetMsg()
 
Select
 
  Case $tsg = $t_ricev
   Stop_alarm()
  
  Case $tsg = $t_end
   Stop_alarm()
   TrayItemDelete($t_end)
   Controlla()
  
EndSelect
 
WEnd
Func Stop_alarm()
 
AdlibUnRegister("Play_sound")
_SoundClose($job_sound)
TrayItemDelete($t_ricev)
 
EndFunc
Func Start_alarm()
 
$t_ricev = TrayCreateItem("Opz1", Default, 0)
$t_end = TrayCreateItem("Opz2", Default, 1)
 
AdlibRegister("Play_sound", _SoundLength($job_sound, 2))
 
EndFunc
Func Play_sound()
 
_SoundPlay($job_sound)
 
EndFunc

[Mjolnir]

Try "TrayAutoPause" option for AutoItSetOption().

[Floppy]

Same result.

[Floppy]

Anyone help me?

[Melba23]

FSoft,

The tray menu is modal (like all menus) - that means it blocks execution of the script until the menu is closed. So your entire script (including the Adlib function) ceases until you close the menu. This is a Windows "feature" and not a bug in Autoit - the same thing happens when you move a window - the script running within it is paused until the window is released.

However, you can get round this problem by using a Timer like this:

expandcollapse popup

#include <GUIConstantsEx.au3> ; GUIConstants.au3 is deprecated <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
#include <Sound.au3>
#Include <Timers.au3> ; New include file <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

Opt("TrayMenuMode", 3)
;Opt("TrayAutoPause", 0) ; Not needed - read the Help file carefully <<<<<<<<<<<<<<<<<<<<<<<<<

$acc_job_sound = "M:\Downloads\Test.mp3"
Global $t_ricev
Global $t_end
Global $iTimer ; Add this <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
Global $job_sound = _SoundOpen($acc_job_sound)

TrayCreateItem("")
$t_chiudi = TrayCreateItem("Chiudi")

$hGUI = GUICreate("Test", 1, 1)
GUISetState(@SW_HIDE)

Start_alarm()

While 1

    Switch TrayGetMsg()
        Case $t_chiudi
            _Timer_KillAllTimers($hGUI) ; Do not forget to kill all timers on exit <<<<<<<<<<<<
            Exit

        Case $t_ricev
            Stop_alarm()

        Case $t_end
            Stop_alarm()
            TrayItemDelete($t_end)
            ;Controlla()

    EndSwitch

WEnd

Func Stop_alarm()

    _Timer_KillTimer($hGUI, $iTimer) ; Kill the timer <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    ;AdlibUnRegister("Play_sound")

    _SoundClose($job_sound)
    TrayItemDelete($t_ricev)

EndFunc   ;==>Stop_alarm

Func Start_alarm()

    $t_ricev = TrayCreateItem("Opz1", Default, 0)
    $t_end = TrayCreateItem("Opz2", Default, 1)

    $iTimer = _Timer_SetTimer($hGUI, _SoundLength($job_sound, 2), "Play_sound") ; Start a timer <<<<<<<<<<<<<<<<
    ;AdlibRegister("Play_sound", _SoundLength($job_sound, 2))

    _SoundPlay($job_sound)

EndFunc   ;==>Start_alarm

Func Play_sound($hWnd, $Msg, $iIDTimer, $dwTime) ; Yes you do need all these parameters! <<<<<<<

    #forceref $hWnd, $Msg, $iIDTimer, $dwTime

    _SoundStop($job_sound) ; Stop the sound before replaying it <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
    _SoundPlay($job_sound)

EndFunc   ;==>Play_sound

I think the comments are clear enough - please ask if not.

M23

[Floppy]

Thank you Melba. Please can you help me with the same thing in the following script?

expandcollapse popup

#include <GUIConstantsEx.au3>
#Include <IE.au3>
#Include <String.au3>
#include <Array.au3>
#include <INet.au3>
#include <Date.au3>
#Include <Timers.au3>
Opt("TrayMenuMode", 3)

$intervallo = 1000

$m_gui = GUICreate("Test", 800, 600)
$IE = ObjCreate("Shell.Explorer.2")
GUICtrlCreateObj($IE, 0, 0, 800, 600)
GUISetState(@SW_SHOW)

TrayCreateItem("")
$t_chiudi = TrayCreateItem("Chiudi")
Controlla()
While 1

$msg = GUIGetMsg()
$tsg = TrayGetMsg()

Select
 
  Case $msg = $GUI_EVENT_CLOSE Or $tsg = $t_chiudi
    _Timer_KillAllTimers($m_gui)
   Exit
  
EndSelect

WEnd
Func Controlla()
 
  Do
   Global $login_src = _INetGetSource("http://google.com")
  
   $jobs_found = StringInStr($login_src, '<ol>')
   Sleep($intervallo)
  
  Until $jobs_found <> 0
  
  Cerca()
 
EndFunc

Func Cerca()

MsgBox(0,'','ciao')
EndFunc

I tried to implement a timer here too, but, for a strange reason, seems like the script freezes at a point (the window title becomes "Test - Not responding").

[Melba23]

FSoft,

Where is the Timer - and why do you need one?

Furthermore there is no way you ever get to poll Tray or GUI events as you seem to be locked inside the Controlla function. What exactly are you trying to do here?

M23

[Floppy]

This is a piece of a script of mine.

The function Controlla() just search the source of a page ($login_src) for a string ($jobs_found). When that string is found another function is called (Cerca()).

The problem is that when the Do loop inside Controlla() function is running every 1 second, I can't close the program because the program is freezed.

I hope now everything is clear...

[Melba23]

FSoft,

Just look for GUI and Tray events within the function instead of Sleeping - look for the <<<<<<< lines:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <IE.au3>
#include <String.au3>
#include <Array.au3>
#include <INet.au3>
#include <Date.au3>
 
Opt("TrayMenuMode", 3)
 
$intervallo = 1000
 
$m_gui = GUICreate("Test", 800, 600)
$IE = ObjCreate("Shell.Explorer.2")
GUICtrlCreateObj($IE, 0, 0, 800, 600)
GUISetState(@SW_SHOW)
 
TrayCreateItem("")
$t_chiudi = TrayCreateItem("Chiudi")
 
Controlla()
 
While 1
 
    $msg = GUIGetMsg()
    $tsg = TrayGetMsg()
    Select
        Case $msg = $GUI_EVENT_CLOSE Or $tsg = $t_chiudi
            Exit
    EndSelect
 
WEnd
Func Controlla()
 
    Do
        Global $login_src = _INetGetSource("http://google.com")
 
        $jobs_found = StringInStr($login_src, '<ol>')
 
        ; Here we wait for the delay time  ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
        $iBegin = TimerInit()
        While TimerDiff($iBegin) < $intervallo
 
            ; But do things while we wait
            $msg = GUIGetMsg()
            $tsg = TrayGetMsg()
            Select
                Case $msg = $GUI_EVENT_CLOSE Or $tsg = $t_chiudi
                    Exit
            EndSelect
        WEnd  ; <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
 
    Until $jobs_found <> 0
 
    Cerca()
 
EndFunc   ;==>Controlla
 
Func Cerca()
    MsgBox(0, '', 'ciao')
EndFunc   ;==>Cerca

No timers needed now. All clear?

M23

[Floppy]

Melba if I set the $intervallo to 1000 it works fine, but if I try to set it to 5000 for example, it doesn't work except if you don't click Close every 5 seconds...

[Melba23]

FSoft,

it doesn't work except if you don't click Close every 5 seconds

What does not work? You only need to click "Close" if you want to exit!

And there is no reason at all why the length of the delay should have any effect at all on the script other than setting the interval between reading the source from the URL.

Are you trying to say that the script pauses if you open the tray menu? If so then I have already shown you how to get over that problem by using a Timer. If not than please explain a little more clearly.

I am very willing to help but I need to understand the problem you are having.

M23

[Floppy]

Thank you Melba. LOL I just made a mistake copying/pasting your version of the script. LOL

Now I have another problem. I'm trying to close the program only when the Close button of a window is pressed.

I made this, but it doesn't work.

#include <GUIConstantsEx.au3>

Opt("TrayMenuMode", 3)

$m_gui = GUICreate("Test", 800, 600)
GUISetState(@SW_SHOW, $m_gui)
$q_gui = GUICreate("Prova", 800, 600)
GUISetState(@SW_SHOW, $q_gui)

While 1

    $msg = GUIGetMsg(1)
    Select
  Case $msg = $GUI_EVENT_CLOSE
   MsgBox(0,'',$msg[1])
            Exit
    EndSelect

WEnd

[BrewManNH]

GUIGetMsg ( [advanced] )

advanced [optional] return extended information in an array.

0 = (default) Returns a single event.

1 = returns an array containing the event and extended information.

Your case statement is incorrect, if you're using the advanced parameter, you need to refer to the $msg as an array, not as a variable. Edited November 5, 2011 by BrewManNH

[Floppy]

I tried this but it doesn't work again:

expandcollapse popup

#include <GUIConstantsEx.au3>
Global $about_gui

Opt("TrayMenuMode", 3)

$m_gui = GUICreate("Test", 800, 600)
GUISetState(@SW_SHOW, $m_gui)
$q_gui = GUICreate("Prova", 800, 600)
GUISetState(@SW_SHOW, $q_gui)

While 1

    $msg = GUIGetMsg(1)
   Switch $msg[1]
    
  Case $m_gui
     
   Select
      
    Case $msg = $GUI_EVENT_CLOSE
     Exit
      
   EndSelect
     
  Case $about_gui
     
   Select
     
    Case $msg = $GUI_EVENT_CLOSE
     GUIDelete($about_gui)
      
   EndSelect
     
    
EndSwitch

WEnd

[BrewManNH]

You create 2 GUIs, $m_gui and $q_gui, there's no $about_gui in your script.

Then you're still not using the GUIGetMsg return array correctly in your checks for messages. See if this doesn't work better for you than how you wrote it.

#include <guiconstantsex.au3>
Global $about_gui=9999

Opt("TrayMenuMode", 3)

$m_gui = GUICreate("Test", 800, 600)
GUISetState(@SW_SHOW, $m_gui)
$q_gui = GUICreate("Prova", 800, 600)
GUISetState(@SW_SHOW, $q_gui)

While 1
    $msg = GUIGetMsg(1)
    Switch $msg[1]
        Case $m_gui
            Select
                Case $msg[0] = $GUI_EVENT_CLOSE ; <<<<<<< $msg is still an array, check it correctly
                    Exit
            EndSelect
        Case $q_gui ; <<<<<<<< you don't create a gui and assign it to a variable named $about_gui, check the correct variables
            Select
                Case $msg[0] = $GUI_EVENT_CLOSE
                    GUIDelete($q_gui) ; <<<<<<<<< close the correct window
            EndSelect
    EndSwitch
WEnd

Edited November 6, 2011 by BrewManNH

[Floppy]

Thank you, now it works

[Floppy]

Another problem I noticed today.

If I run every 1 second appears the loading cursor. Is possible to prevent this?

[Floppy]

Noone knows the solution?

[Floppy]

?

[BrewManNH]

It's showing the loading cursor because it's loading the web site in the Controlla function (Global $login_src = _INetGetSource(http://google.com)) inside the Do loop in that function. The only way to avoid that is to not try to load a web page every time through the Do loop I would assume.