Checking restore / maximize state of GUI

[Mikeman27294]

Hey, I am just wondering about how I would check whether the current GUI is maximized or restored? Right now, I am using GUI Events to change a variable, I am wondering whether there is a more efficient way?

Thanks.

[AdmiralAlkex]

I am not sure what you are asking for, but try WinGetState()

[Mikeman27294]

Thanks. The problem is that WinGetState() will only return if the GUI is Maximized or Minimized. I also want to detect if the window is restored, because then I have different resizing settings for the window.

[BrewManNH]

Try using GUIRegisterMsg and monitoring the restore operation.

[AdmiralAlkex]

Thanks. The problem is that WinGetState() will only return if the GUI is Maximized or Minimized. I also want to detect if the window is restored, because then I have different resizing settings for the window.

Well, if it's restored then it's not maximized, right?

But if you want to respond to your own window restoring in your script, then GUIRegisterMsg with WM_SYSCOMMAND (I think it's that message) is the way to go.

Try it, and if you get stuck, show us some code and blah blah, you know the drill

[Mikeman27294]

Ok, thanks. I will give that a shot then.

[BrewManNH]

Mikeman, take a look at the link I have in my signature if you're unsure of how to use GUIRegisterMsg command functions. The demo includes a way of showing how to see when a window is restored, as an example.

[Mikeman27294]

Nah I have a good idea on how to use GUIRegisterMsg, but thanks for pointing me towards it though. If I muck up, I will check there first.

Well out of pure curiosity, I changed my mind and took a look at it. That is definately an interesting way of doing it. But I think it might conflict with the way that I am doing it. But, thanks again.

Edited February 2, 2012 by Mikeman27294

[Mikeman27294]

Ok everyone, back again. This is the code I used:

GUISetOnEvent($GUI_EVENT_RESTORE, '_RestoreWindow')
GUISetOnEvent($GUI_EVENT_MAXIMIZE, '_MaximizeWindow')
;tonnes of code
Func _RestoreWindow()
    $MAXIMIZERESTORE = 0
EndFunc
Func _MaximizeWindow()
    $MAXIMIZERESTORE = 1
EndFunc

$MaximizeRestore is a global variable.

The problem is though, that when I ran it through a debugger, I noticed that minimizing and then maximizing the window plays around with the variable, and if it is maximizing from the task bar, the program gets the restore message, which means that restore is not only leaving the maximized state, but also un-minimizing the window. That makes sense since the help file tells me that the restore variable is this action: dialog box restored by click on task bar icon.

The command I should look for, I assume would be named WM_RESTOREDOWN but that command doesn't seem to exist?

And by looking at your script, Brewman, I enabled the restore down / maximize button. It has given me the following data:

MsgID = 274

wParam = 0x0000F030

lParam = 0x00FF02DE

Code = 0

CtrlID = 61488

CtrlHWnd = 0x00FF02DE

Can any of that information be used to set an event? For example, could I use the MsgID to assign it to a function?

Sorry for flooding with information, but I just took another look, compared the codes. It seems that the wparam and lparam changed for both minimizing and maximizing when I ran the script the second time, as did the CTRLID, but the msgID stayed the same, so I assume, as I had expected, that this is what I have to use.

Edited February 2, 2012 by Mikeman27294

[BrewManNH]

If you look in that demo script from post #4 in that thread, you will see that you can look for the Windows Message being sent, in your case you'd look for $WM_SYSCOMMAND messages for minimize/restore/maximize of the window. Once you've determined that you have the right message you'd look for the wparam message which tells you what the GUI is doing,

0xF020 = Minimize

0xF120 = Restore

0xF030 = Maximize

Looking further at the demo script, you can see that all I am doing with the information is sending text to the Console window in SciTe but you could use the method to run a function or set a variable that runs a function a certain way later in your script. As long as you remember to not try and run any long running or blocking functions from within the message function.

[Mikeman27294]

Yes, I noticed that it is doing the consolewrite, and I noticed the minimize restore and maximize flags. The problem is though, that restoring from maximized and restoring from minimized are 2 different things. The restore (0xF120) is restoring from the taskbar, not from maximized.

[BrewManNH]

In Windows parlance, restoring from the taskbar and from Maximized is the same thing.

[Mikeman27294]

Ok. Thanks.

That's going to be a bit of a problem for me then. Maybe it will work if I use the desktopheight and desktopwidth macros.

Thanks everyone.

[BrewManNH]

You can set a variable to tell you that the window was minimized or maximized and when you get the restore message you'll know what it did last. Just remember, it can be maximized and then minimized and then restored, minimized then maximized and then restored so make sure you're keeping track of the last state it was in. Also, for some bizarre reason, you can't minimize or maximize a program window from the taskbar button by right clicking it in Windows 7, so I guess you can't minimize then maximize in that OS.

[AdmiralAlkex]

Also, for some bizarre reason, you can't minimize or maximize a program window from the taskbar button by right clicking it in Windows 7, so I guess you can't minimize then maximize in that OS.

Yes you can. Rightclick the thumbnail, not the taskbar item.

[BrewManNH]

Yes you can. Rightclick the thumbnail, not the taskbar item.

Well, you learn something new every day. I never knew you could do that with Windows 7 like that, i'm so used to doing it with the taskbar buttons I never thought about the pop up window.

[UEZ]

I don't know whether you got it already working but here the code for the checking restore / maximize state of the GUI.

#Include <WindowsConstants.au3>
#Include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 640, 480, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX))
GUISetState()

GUIRegisterMsg($WM_SYSCOMMAND, "WM_SYSCOMMAND")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

GUIDelete($hGUI)
Exit

Func WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)
    Switch BitAND($wParam, 0x0000FFFF)
        Case 0xF020
            ConsoleWrite("Window was minimized" & @LF)
        Case 0xF120
            ConsoleWrite("Window was restored" & @LF)
        Case 0xF030
            ConsoleWrite("Window was maximized" & @LF)
    EndSwitch
    Return "GUI_RUNDEFMSG"
EndFunc

Br,

UEZ

[Mikeman27294]

You can set a variable to tell you that the window was minimized or maximized and when you get the restore message you'll know what it did last. Just remember, it can be maximized and then minimized and then restored, minimized then maximized and then restored so make sure you're keeping track of the last state it was in. Also, for some bizarre reason, you can't minimize or maximize a program window from the taskbar button by right clicking it in Windows 7, so I guess you can't minimize then maximize in that OS.

Yes, that's what I was doing. The problem is though, that when you restore the program (whether it be to full screen or not) it is set to the non-full screen restored state.

By the way, hold shift and click on the taskbar icon. You'll understand once you have done it.

I don't know whether you got it already working but here the code for the checking restore / maximize state of the GUI.

#Include <WindowsConstants.au3>
#Include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 640, 480, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX))
GUISetState()

GUIRegisterMsg($WM_SYSCOMMAND, "WM_SYSCOMMAND")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

GUIDelete($hGUI)
Exit

Func WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)
    Switch BitAND($wParam, 0x0000FFFF)
        Case 0xF020
            ConsoleWrite("Window was minimized" & @LF)
        Case 0xF120
            ConsoleWrite("Window was restored" & @LF)
        Case 0xF030
            ConsoleWrite("Window was maximized" & @LF)
    EndSwitch
    Return "GUI_RUNDEFMSG"
EndFunc

Br,

UEZ

Yes, I tried that, thanks. The problem I am having though, is that restore from maximize and restore from minimized are exactly the same. I think what I might do, is set it to detect if the window is active (when restored) and see if that works for me.

Ok, made a small alteration to the code. I feel this is a bit of a dirty work-around and was trying to avoid it but I am certain that ti won't cause errors.

#Include <WindowsConstants.au3>
#Include <GUIConstantsEx.au3>

$hGUI = GUICreate("Test", 640, 480, -1, -1, BitOR($GUI_SS_DEFAULT_GUI, $WS_MAXIMIZEBOX))
GUISetState()
$PreviousState = 1

GUIRegisterMsg($WM_SYSCOMMAND, "WM_SYSCOMMAND")

Do
Until GUIGetMsg() = $GUI_EVENT_CLOSE

GUIDelete($hGUI)
Exit

Func WM_SYSCOMMAND($hWnd, $Msg, $wParam, $lParam)
    Switch BitAND($wParam, 0x0000FFFF)
        Case 0xF020
            ConsoleWrite("Window was minimized" & @LF)
            $PreviousState = 0
        Case 0xF120
            If $PreviousState = 2 Then
                ConsoleWrite("Window was restored from maximized" & @LF)
            ElseIf $PreviousState = 0 Then
                ConsoleWrite("Window was restored from the taskbar" & @LF)
            Else
                ConsoleWrite('Error ' & $PreviousState & @LF)
            EndIf
            $PreviousState = 1
        Case 0xF030
            ConsoleWrite("Window was maximized" & @LF)
            $PreviousState = 2
    EndSwitch
    Return "GUI_RUNDEFMSG"
EndFunc

Edited February 3, 2012 by Mikeman27294