wrong event is firing

[rodent1]

When I click on the listview item #5 of my script, the wrong event is fired.

I have removed as many factors to this problem as I could. This was happening in a larger script, and it took me a while to figure out that the reason the script would unload when I'd click that item #5 is that it fires the menu file->exit of the script.

So I created a sample script to reproduce this. I have a listview, a button to populate it, and a menu.

After it is populated with at least 5 items, click on the listview's 5th item (not the 4th, not the 6th), and the menu File->exit event fires.

I have reproduced this with AutoIT 3.3.6.1 original, and with the latest beta, on 2 different machines.

Does this happen to you as well?

Any idea what is happening here?

Here is the code:

expandcollapse popup

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Include <GuiListView.au3>
Dim $Form, $btnAdd, $lvFiles
ShowGui()
Func ShowGui()
$Form = GUICreate("HMM", 623, 442, 192, 124)
$mnuF = GUICtrlCreateMenu("&File")
$mnuF_Exit = GUICtrlCreateMenuItem("E&xit" & @TAB & "Alt-F4", $mnuF)
$btnAdd = GUICtrlCreateButton("Add To List", 104, 8, 133, 33)
$lvFiles = GUICtrlCreateListView("File Name", 2, 48, 617, 330)
GUISetState(@SW_SHOW)
While 1
  $nMsg = GUIGetMsg()
  Switch $nMsg
   Case $GUI_EVENT_CLOSE
    Exit
   case $mnuF_Exit
    MsgBox(0,"","File->exit was selected. Exiting now...")
    Exit
   case $btnAdd
    AddToList()
  EndSwitch
WEnd
EndFunc
Func AddToList()
Dim $FileList = FileOpenDialog("New List Item", @ScriptDir, "All Files (*.*)", 7) ; 7=file and path must exist, allow multiselect
if StringLen($FileList)=0 then Return
Dim $ItemCount = _GUICtrlListView_GetItemCount($lvFiles)
if StringInStr($FileList, "|") Then ; multiple file user selection
  Dim $arFiles = StringSplit($FileList, "|")
  Dim $RowIndex
  for $i=2 to $arFiles[0]
   $RowIndex = _GUICtrlListView_AddItem($lvFiles, $arFiles[$i], -1, $ItemCount)
   $ItemCount += 1
  Next
Else ; single file user selection
  Dim $arToks = StringSplit($FileList, "\")
  Dim $ItemCount = _GUICtrlListView_GetItemCount($lvFiles)
  $RowIndex = _GUICtrlListView_AddItem($lvFiles, $arToks[$arToks[0]], -1, $ItemCount)
EndIf
EndFunc

[BrewManNH]

The reason the wrong event is firing is because the number of the index for the 5th listview item is the same as the number of the control ID of the menu item so when the LV item is clicked GUIGetMsg thinks it's seeing the menu item. Here's a work around:

$RowIndex = _GUICtrlListView_AddItem($lvFiles, $arFiles[$i], -1, 9999 + $ItemCount) ; adding 9999 to the item count allows you to be able to sort the items as well as allows you to avoid the problem with control IDs

[rodent1]

Thanks, BrewManNH, got it!