ListView fields to Input boxes

[MPHillier]

EDIT - initially had incorrect line...Corrected.

Ok, Listview has 5 columns Username,Computername,Timein,Date,Serial. Thought process is to use _GUICtrlListView_GetItemTextString($hListView) to get specific row and take each column input and place each into its own Input box. Then run specific commands off these input boxes.

I was looking at an example and it was used to split the listview and place into new excel file - thought I could do the same to get my needed results. Yet of course I am not getting to get the divided info into the separate input boxes.

Here is my thought process

Func ListInput()

$iItems = [color=#ff0000]_GUICtrlListView_GetItemTextString[/color]($hListView, 1))  ;EDIT - initially had incorrect line...Corrected.[/color]
For $iItem = 0 To $iItems - 1
  $Zf = StringSplit($Zf, "|", 1)
  ;<<<<<<<<<<<<<<<<<<<<<<<< Take string and place into individual input boxes.
EndFunc

If you could point me to an example or another help file to help me work this out I would greatly appreciate it or am I coming at this from a wrong point of view....?

I can get the first columns selected input using $WM_NOTIFY

If $fDblClk = True Then
  $sText = GUICtrlRead($hListView) - 18 ; Read the item
  GUICtrlSetData($LCount, "List Item: " & $sText)
  Local $OutPut = _GUICtrlListView_GetItemText($hListView, $sText)
  GUICtrlSetData($iUserName, $OutPut)
  $fDblClk = False; Reset the flag
EndIf

Thank you.

Edited March 4, 2012 by MPHillier

[Melba23]

MPHillier,

Does this help at all?

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <GuiListView.au3>

Global $aInput[5]

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView("", 10, 10, 480, 300)
_GUICtrlListView_AddColumn($cListView, "Username", 80)
_GUICtrlListView_AddColumn($cListView, "Computername", 80)
_GUICtrlListView_AddColumn($cListView, "Timein", 80)
_GUICtrlListView_AddColumn($cListView, "Serial", 80)
_GUICtrlListView_AddColumn($cListView, "Date", 80)

For $i = 1 To 10
    GUICtrlCreateListViewItem("User " & $i & "|Comp " & $i & "|Time " & $i & "|Serial " & $i & "|Date " & $i, $cListView)
Next

For $i = 0 To 4
    $aInput[$i] = GUICtrlCreateInput("", 10, 350 + (30 * $i), 200, 20)
Next

$cButton = GUICtrlCreateButton("Extract", 300, 350, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cButton
            $iIndex = Number(_GUICtrlListView_GetSelectedIndices($cListView))
            $sText = _GUICtrlListView_GetItemTextString($cListView)
            $aText = StringSplit($sText, "|", 2)
            For $i = 0 To 4
                GUICtrlSetData($aInput[$i], $aText[$i])
            Next
    EndSwitch

WEnd

I have used a button rather than a double-click message handler to save time, but the code is essentially the same. Please ask if you have any questions.

M23

[MPHillier]

This is cool -

To my understanding - breaking it down -

Get index of row being used

$iIndex = Number(_GUICtrlListView_GetSelectedIndices($cListView))

Get text from index\row

$sText = _GUICtrlListView_GetItemTextString($cListView)

Split data using "|" as the delimiter, flag = 2, disable the return count in the first element - effectively makes the array 0-based.

$aText = StringSplit($sText, "|", 2)

Drop into the inputs 0 - 4

For $i = 0 To 4

GUICtrlSetData($aInput[$i], $aText[$i]);Input box - string

To actually break it down clears up so much for understanding whats going on.

This is opening up other ideas to use in the project.

So much Thanks and Aloha!

[Melba23]

MPHillier,

You have understood it correctly.

Good luck with the project.

M23