How to sort listview items?

[Skitty]

Apparently it's not that simple when another process created the entry, this has been baffling me for the past few hours.

Anyone know how to make it sortable?

expandcollapse popup

#include <GuiListView.au3>

If StringInStr($CmdLineRaw, "/Hwnd=", 2) Then
    Global $Hwnd = StringStripWS(StringReplace($Cmdline[$Cmdline[0] - 1], "/Hwnd=", ""), 8)
    Global $CTRL = StringStripWS(StringReplace($Cmdline[$Cmdline[0] - 2], "/CTRL=", ""), 8)
    Global $Entry = StringStripWS(StringReplace($Cmdline[$Cmdline[0]], "/DATA=", ""), 8)
    $Hwnd = ControlGetHandle(HWnd($Hwnd), "", HWnd($CTRL))
    Global $ItemCount = _GUICtrlListView_GetItemCount($Hwnd)
    _GUICtrlListView_AddItem($Hwnd, $Entry)
    _GUICtrlListView_AddSubItem($Hwnd, $ItemCount, @HOUR&":"&@MIN&":"&@SEC, 1)
    Exit 0
EndIf

AutoItSetOption("GUIOnEventMode", 1)
AutoItSetOption("GUIResizeMode", 1)

Global Const $WS_RESIZABLE = 0x00070000
Global $GUI
Global $ListView1

$GUI = WinGetHandle(GUICreate("test", 465, 280, -1, -1, $WS_RESIZABLE))
GUISetOnEvent(-3, "Terminate")
$ListView1 = GUICtrlCreateListView("1|2", 4, 49, 450, 166)
GUICtrlSetOnEvent(-1, "SortIt")
DllCall("USER32.DLL", "lresult", "SendMessageW", "hwnd", GUICtrlGetHandle($ListView1), "uint", 0x1000 + 30, "wparam", 0, "lparam", 120)
GUICtrlCreateButton("Test this", 172, 225, 65, 25)
GUICtrlSetOnEvent(-1, "TEST")
GUISetState(@SW_SHOW)

_GUICtrlListView_RegisterSortCallBack($ListView1)

While 1
    Sleep(100)
WEnd

Func TEST()
        For $I = 0 To 8
            Switch @Compiled
                Case True
                    $ChildPID = Run(FileGetShortName(@ScriptFullPath) & " /CTRL=" & GUICtrlGetHandle($ListView1) & " /Hwnd=" & $GUI & " /DATA=" & $I)
                Case False
                    $ChildPID = Run(FileGetShortName(@AutoItExe) & ' /AutoIt3ExecuteScript "' & @ScriptFullPath & '"' & " /CTRL=" & GUICtrlGetHandle($ListView1) & " /Hwnd=" & $GUI & " /DATA=" & $I)
            EndSwitch
            Sleep(1000)
        Next
    Return 1
EndFunc   ;==>TEST

Func SortIt()
    _GUICtrlListView_SortItems($ListView1, GUICtrlGetState($ListView1))
    Return $__LISTVIEWCONSTANT_GUI_RUNDEFMSG
EndFunc   ;==>SortIt

Func Terminate()
_GUICtrlListView_UnRegisterSortCallBack($ListView1)
    Exit 0
EndFunc   ;==>Terminate

Edited May 14, 2012 by ApudAngelorum

[stormbreaker]

_GuiCtrlListView_SimpleSort, _GuiCtrlListView_SortItems ?

[Skitty]

_GuiCtrlListView_SimpleSort, _GuiCtrlListView_SortItems ?

Apparently it's not as simple as that.

Edited May 14, 2012 by ApudAngelorum

[BrewManNH]

If you add items to the listview using the UDF functions, and you want to make them sortable, you need to add them using a line like this:

_GUICtrlListView_AddItem($Hwnd, $Entry, -1,_GUICtrlListView_GetItemCount($Hwnd) + 9000)

There's an issue with the ListView that requires you to take the current count of the items in the listview, and then add at least 9000 to that number to put the next item in the listview or it won't be sortable.

[Skitty]

I don't know what I'm doing wrong but it's still not working, although I did find a work around involving reading all the entries after the operation has completed and saving them to a variable and deleting the list view and recreating it with the native autoit functions.

[BrewManNH]

I took your script, changed that line that I posted, and it sorts just fine. Also, I missed where you already had gotten the item count of the listview, so you can shorten it further by using this line

_GUICtrlListView_AddItem($Hwnd, $Entry, -1, $ItemCount + 9000)

This replaces your line #9 in the script you posted in the first post.

[Skitty]

Oh crap, you're right, what a surprise.

haha, thanks, this is much better than what I was doing a while ago.

[BrewManNH]

I ran into this problem myself a while ago, couldn't sort the listview because I was adding items using the UDF functions, finally found the answer I gave you after a LOT of false leads going nowhere.