Run batch then wait till it is finished

[juicyjon]

Hi guys, i am having trouble making autoit wait till my batch file is done before moving on with the rest of the script. to run the batch i use this code.

runwait (C:\batch.batch)

i found this in the help file. Any suggestions?

Thanks

[Mechaflash]

RunWait("C:batch.bat")

?

[juicyjon]

Trying to run batch file and then have the rest of the script to continue. Is runwait going to work? Or am i using the wrong command.

[Mechaflash]

A couple of things wrong with your code is the space between the function name and brackets, and no quotations around the file name, so I rewrote it. Does it work now?

[juicyjon]

Sorry mistook the "?" , thought you were asking what i am trying to do sorry. Also no it doesn't wait for the batch to run first, and then continue to the rest of the script.

[Mechaflash]

Can you supply additional au3 code and if possible the batch script code?

[BrewManNH]

How about ShellExecuteWait("c:batch.bat"), does that do what you need?

As a side note, are you sure you actually need to use a batch file for what you're doing? Can it be done all in AutoIt?

[Mechaflash]

As a side note, are you sure you actually need to use a batch file for what you're doing? Can it be done all in AutoIt?

My thoughts exactly. After learning about AutoIT, I converted all my batch scripts.

[juicyjon]

I tried to make the batch into an autoit script but it did not give me the desired results . So it was easier for me to create a batch and then have autoit run it. Here is the batch if you are interested.

@echo off
if exist c:fwiplist.txt goto Label1
echo.
echo Cannot find c:fwiplist1.txt
echo.
Pause
goto :eof
:Label1
for /f %%i in (c:fwiplist1.txt) do call :Sub %%i
goto :eof
:Sub
set state=alive
ping -n 1 %1 | find /i "bytes=" || set state=dead
if %state%==alive echo %1 is %state% >> c:results.txt
if %state%==dead echo %1 is %state% >> c:results.txt

Water the shellexecutewait worked. Thanks , also if you have a suggestion on turning my batch into a script (if i can) i would appreciate it. Also thanks for the help.

Jon

[BrewManNH]

Try this:

#include <File.au3>
Global $aFile
If Not FileExists("c:fwiplist.txt") Then
    MsgBox(64, "Error", "Cannot find c:fwiplist1.txt")
    Exit
EndIf
_FileReadToArray("c:fwiplist.txt", $aFile)
$File = FileOpen("C:results.txt", 1)
For $I = 1 To $aFile[0]
    If Not Ping($aFile[$I]) Then
        FileWriteLine($File, $aFile[$I] & " is dead" & @CRLF)
    Else
        FileWriteLine($File, $aFile[$I] & " is alive" & @CRLF)
    EndIf
Next
FileClose($File)

[Mechaflash]

bored ftw

expandcollapse popup

#include <File.au3>

$sFile = "C:fwiplist.txt"
$sResults = "C:results.txt"

If FileExists($sFile) Then
    _Sub()
    Exit
Else
    msgbox(16 + 262144, "Script", "Cannot find " & $sFile)
    Exit
EndIf


Func _Sub()
    Local $asIP
    Local $iTimeout = "2000" ;Whatever timeout value you want
    If FileExists($sResults) Then FileMove($sResults, "C:results-" & @YEAR & @MON & @MDAY & @HOUR & @MIN & @SEC & ".txt")
    $hResults = FileOpen($sResults, 1)
    _FileReadToArray($sFile, $asIP)
    ProgressOn("Scanning IPs", "Checking IP Addresses From File", "Please Wait...")
    For $i = 1 To $asIP[0]
        If Ping($asIP[$i], $iTimeout) Then
            Sleep(100)
            FileWrite($hResults, "ALIVE: " & $asIP[$i] & @CRLF)
        Else
            $iError = @error
            Switch $iError
                Case 1
                    $sError = "Host Offline"
                Case 2
                    $sError = "Host Unreachable"
                Case 3
                    $sError = "Bad Destination"
                Case 4
                    $sError = "Other Error"
            EndSwitch

            FileWrite($hResults, "DEAD: " & $asIP[$i] & " - Error: " & $iError & " = " & $sError & @CRLF)
        EndIf
        ProgressSet(Round($i / $asIP[0] * 100), Round($i / $asIP[0] * 100) & "% Complete", "Checking IP Addresses From File")
    Next
    ProgressSet(100, "DONE!", "IP Check Complete")
    Sleep(2000)
    FileClose($hResults)
EndFunc

Edited May 25, 2012 by mechaflash213

[juicyjon]

Cool Thanks Mechflash.