Setting up an loop for a timed pop-up GUI

[rowish]

Hello,

My struggle to work out a custom pop-up window is in vain. I want to build a GUI which provides a window that is hidden for a certain interval of time and then pops-up to remind the user a repetitive activity. The user should be able to acknowledge the message unless he ignores the pop-up so its time-out will hide it again to resume the cycle. All seams to be sorted out excepting the loop which hides and shows the pop-up after initial start. Trying to enclose it in a logical loop seems to mess up the timers and to brake the GUIGetMsg() function, so there is no control over GUI.

Here is the code:

#include <GUIConstantsEx.au3>
#include <Timers.au3>

Local $OK, $Exit, $msg

$hGUI = GUICreate("Vision Saver", 190, 65)
GUICtrlCreateLabel("It's time for a brake!", 10, 10)
$OK = GUICtrlCreateButton("OK", 10, 30, 80, 20)
GuiCtrlSetState (-1, 512)
$Exit = GUICtrlCreateButton("Exit", 100, 30, 80, 20)

GUISetState() ; Initial display

While 1
   $msg = GUIGetMsg()
   Switch $msg
      Case $OK
            GUISetState(@SW_HIDE)
            Sleep(5000)
            GUISetState(@SW_SHOW) ;First popup after delay;
            _Timer_SetTimer($hGUI, 2000, "Autohide", -1) ;Set timeout if user do not interfere
            ;Placehlder for the loop
      Case $Exit
            GUIDelete()
            Exit
      Case $GUI_EVENT_CLOSE
            GUIDelete()
            Exit
   EndSwitch
WEnd

Func Autohide($hWnd, $Msg, $iIDTimer, $dwTime)
   GUISetState(@SW_HIDE)
EndFunc

Anybody could help me, please?

Thank you in advance.

[Melba23]

rowish,

You are overcomplicating things:

; Set a timestamp
$iBegin = TimerInit()

While 1
    ; Has enough time passed?
    If TimerDiff($iBegin) > 5000 Then ; Currently set to 5 secs for testing
        ; Reset the timestamp
        $iBegin = TimerInit()
        ; Show the dialog
        MsgBox(0, "Vision Saver", "Time for a break", 2) ; Times out after 2 secs
    EndIf
WEnd

Please ask if you have any questions.

M23

[BrewManNH]

This script will show the GUI every 10 seconds, and if not acted on will hide it in 2 seconds. I have included 2 ways of doing it, the current way uses one function to show and hide the GUI, but I've also included a way to do it with 2 separate functions that set each other. This uses the Adlib functions to do the timing.

The reason I included the 2 function version as well is in case you want to do something else other than just hiding/showing the GUI while this is running.

expandcollapse popup

#include <GUIConstantsEx.au3>
;~ Comment out the following line, and uncomment the line after it for the 2 function method
AdlibRegister("AutoShowHide", 10000) ; sets timer so the GUI shows every 10 seconds
;~ AdlibRegister("AutoShow", 10000) ; sets timer so the GUI shows every 10 seconds
Local $OK, $Exit, $msg

$hGUI = GUICreate("Vision Saver", 190, 65)
GUICtrlCreateLabel("It's time for a break!", 10, 10)
$OK = GUICtrlCreateButton("OK", 10, 30, 80, 20)
GUICtrlSetState(-1, 512)
$Exit = GUICtrlCreateButton("Exit", 100, 30, 80, 20)
While 1
     $msg = GUIGetMsg()
     Switch $msg
          Case $OK
               ;~ Comment out the following line, and uncomment the line after it for the 2 function method
               Autoshowhide() ; hides the GUI
;~                AutoHide()
          Case $Exit, $GUI_EVENT_CLOSE
               GUIDelete()
               Exit
     EndSwitch
WEnd
;~ Uncomment the following 2 functions if using the 2 function method
;~ Func Autohide()
;~      AdlibUnRegister("AutoHide") ; Unregisters the AutoHide timer
;~      GUISetState(@SW_HIDE)
;~      AdlibRegister("AutoShow", 10000) ; Reregisters the AutoShow timer
;~ EndFunc   ;==>Autohide
;~ Func AutoShow()
;~      AdlibUnRegister("AutoShow") ; Unregisters the AutoShow timer
;~      GUISetState(@SW_SHOW)
;~      AdlibRegister("AutoHide", 2000) ; Registers the AutoHide timer, set to 2 seconds
;~ EndFunc   ;==>AutoShow
;~ You can comment out the following function if using the 2 function method, but not really needed
;~ because it won't be used if you followed the instructions above.
Func AutoShowHide()
     Local Static $Toggle
     $Toggle = Not $Toggle
     If $Toggle Then
          GUISetState(@SW_SHOW)
          AdlibRegister("AutoShowHide", 2000) ; Resets the AutoShowHide timer to 2 seconds
     Else
          GUISetState(@SW_HIDE)
          AdlibRegister("AutoShowHide", 10000) ; Resets the AutoShowHide timer to 10 seconds
     EndIf
EndFunc   ;==>AutoShowHide

[rowish]

I simply love this forum. Thank you, M23! Thank you, BrewMan!

[Melba23]

rowish,

Glad we could help.

M23