_GUICtrlListView_SetColumnWidth last column ignores specified width

[abberration]

Hi, all. I have 2 listviews with 2 columns each. One listview has shorter words, so there is no horizonal scrollbar. But the 2nd listview has longer words, so a horizontal scrollbar is inserted. The help file says the last column adjusts itself to fit the text. I do not want that. I would rather the text be cut off like it is in column 1.

Does anyone know of any tricks to force the last column to be a specified size?

Alternatively, is there a way to keep the vertical scrollbars, but disable the horizontal?

Thanks!

Edited February 1, 2013 by abberration

[BrewManNH]

I'm guessing you didn't actually try this did you?

Because _GUICtrlListView_SetColumnWidth will adjust any column to any width you specify.

[abberration]

I'm guessing you didn't actually try this did you?

Because _GUICtrlListView_SetColumnWidth will adjust any column to any width you specify.

Yes, I did try it. And it did not set the last column width smaller than the longest word.

I don't think there will be a workaround. I've tried a lot of things. I am simply making my GUI larger and the listviews larger as well.

Thanks for trying to help, BrewManNH!

[BrewManNH]

GUICtrlListView_SetColumnWidth($hListView, 3, 1) will set the 4th column of a 4 column listview to 1 pixel wide. The listview itself doesn't change size but the 4th column does.

[abberration]

What you suggested is one of the things that I tried. That doesn't work, either. Example:

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Form1", 633, 447, 193, 125)
$ListView1 = GUICtrlCreateListView("From|To||", 136, 72, 170, 150, BitOR($LVS_REPORT,$LVS_SINGLESEL,$LVS_SHOWSELALWAYS,$WS_VSCROLL))
_GUICtrlListView_SetColumnWidth($ListView1, 0, 60)
_GUICtrlListView_SetColumnWidth($ListView1, 1, 60)
_GUICtrlListView_SetColumnWidth($ListView1, 2, 1)
_GUICtrlListView_SetColumnWidth($ListView1, 3, 1)
GUICtrlCreateListViewItem("60 wide|not 60 wide", $ListView1)
GUICtrlCreateListViewItem("ajweighweirjniwerjgvb|ejfgbioerewfghaerherherhiojgbeio", $ListView1)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Edited February 1, 2013 by abberration

[BrewManNH]

#include <GUIConstantsEx.au3>
#include <ListViewConstants.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#include <GuiListView.au3>

$Form1 = GUICreate("Form1", 633, 447, 193, 125)
$ListView1 = GUICtrlCreateListView("From|To||", 136, 72, 170, 150, BitOR($LVS_REPORT,$LVS_SINGLESEL,$LVS_SHOWSELALWAYS,$WS_VSCROLL))
GUICtrlCreateListViewItem("60 wide|not 60 wide||", $ListView1)
GUICtrlCreateListViewItem("1234567890|1234567890", $ListView1)
_GUICtrlListView_SetColumnWidth($ListView1, 0, 60)
_GUICtrlListView_SetColumnWidth($ListView1, 1, 60)
_GUICtrlListView_SetColumnWidth($ListView1, 2, 1)
_GUICtrlListView_SetColumnWidth($ListView1, 3, 1)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

This should do what you're looking for. Try setting the width after you've filled the listview.

[abberration]

Wow, BrewManNH! Your method worked. I tried something similar before, but my attempt didn't work. But your example works, so I will go with your working method.

Thanks for all your help. Much appreciated!