Populete listview from ini file

[Copyrigth]

Hi,

I was wondering if there is a way to populate an listview using ini file?

My ini file looks like this:

[copmuter1]
user=student
OS=win7

[copmuter2]
user=Admin
OS=winxp

Edited March 14, 2013 by Copyrigth

[BrewManNH]

Yes there is.

[Copyrigth]

Yes there is.

Can you please point me in the direction?

[BrewManNH]

It depends on what you want the listview to look like with the data you have. 1 column, 2 columns, 3 columns? User name in one column and computer name in another, and/or with the OS version in a third for instance. Give me something to work with rather than ask if it's possible with no clue what you're looking to do with the data.

[Copyrigth]

I was thinking about what you described, with 3 collums

like this:

Field1 | Field2 | Field3

User | computername | OS

[kylomas]

copyrigth,

This should get you started...

expandcollapse popup

; *** Start added by AutoIt3Wrapper ***
#include <Constants.au3>
#include <GUIConstantsEx.au3>
; *** End added by AutoIt3Wrapper ***

#include <array.au3>

#AutoIt3Wrapper_Add_Constants=n

local $iniFile = @scriptdir & '\computers.ini'
local $aSections = IniReadSectionNames($iniFile)

if not isarray($aSections) then
    msgbox($mb_ok,'INI READ Section Names ERROR','File = ' & $iniFile)
    Exit
endif

local $gui010   =   guicreate('INI to ListView control Example')
local $aGuiSize =   wingetclientsize($gui010)
local $lv010    =   guictrlcreatelistview('Computer|Student|OpSys',20,20,$aGuiSize[0]-40,$aGuiSize[1]-40)
                    guisetstate()

; populate listview

local $aSection, $sLVItem

for $1 = 1 to $aSections[0]
    $aSection = inireadsection($iniFile,$aSections[$1])
    if @error = 1 then
        msgbox($mb_ok,'INI READ Section ERROR','File = ' & $iniFile)
        Exit
    endif

    for $2 = 1 to $aSection[0][0]
            $sLVItem &= $aSection[$2][1] & '|'
    next

    if guictrlcreatelistviewitem($aSections[$1] & '|' & $sLVItem,$lv010) = 0 then
        msgbox($mb_ok,'ListView Item Create ERROR','Item = ' & $aSections[$1] & '|' & $sLVItem)
        Exit
    endif

    $sLVItem = ''

next

while 1
    switch guigetmsg()
        case $gui_event_close
            Exit
    EndSwitch
wend

kylomas

edit: the ini file looks like this

[copmuter1]
user=student001
OS=win7
[copmuter2]
user=Admin
OS=winxp
[copmuter3]
user=student009
OS=win7
[copmuter4]
user=dumb ass student
OS=win7
[copmuter5]
user=M23
OS=win7

Edited March 14, 2013 by kylomas

[Copyrigth]

Thank you so much kylomas

[kylomas]

My pleasure, now it's your turn. If you don't understand something, look it up in the HELP file and see how it works within the context of this script.

Good Luck,

kylomas

[Copyrigth]

Will do