Sum Hex value of Array

[MyEarth]

Hi i have this script:

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

Global $aArray[8] = ["0x01", "0x02", "0x04", "0x08", "0x10", "0x20", "0x40", "0x80"]
Global $NumberExample = 4
Global $Checkbox_[$NumberExample + 1]
Global $Label_[$NumberExample + 1]
$hGUI = GUICreate("Form1", 347, 270, 192, 124)
$Button = GUICtrlCreateButton("Check", 256, 232, 75, 25)

For $i = 0 To $NumberExample - 1
$Checkbox_[$i] = GUICtrlCreateCheckbox("", 8, 8 + (25 * $i), 15, 15)
$Label_[$i] = GUICtrlCreateLabel("Value " & $i, 25, 9 + (25 * $i), 50, 20)
Next
GUISetState(@SW_SHOW)

While 1
$nMsg = GUIGetMsg()
Switch $nMsg
Case $GUI_EVENT_CLOSE
Exit
Case $Button
Local $Value = "", $FinalHex = 0
For $i = 0 To $NumberExample - 1
If GUICtrlRead($Checkbox_[$i]) = $GUI_CHECKED Then
     $Value &= $aArray[StringRight(GUICtrlRead($Label_[$i]), 1)] & "|"
EndIf
Next
$aValue = StringSplit($Value, "|")
If $aValue[0] = 2 Then ; One elemen selected Then
Global $FinalHex = $aValue[1]
EndIf
MsgBox(0,0,$FinalHex)
EndSwitch
WEnd

If i select one checkbox i have the correct value, but the problem is i don't know how to sum two or more value of two or more checkbox, exmaple:

I select the first checkbox = Value 0 = 0x01 ( in the script i have do it, don't know the method is correct

I select all checkbox = Value 0 ( 0x01 = 1 ) + Value 1 (0x02 = 2 ) + Value 2 (0x04 = 4 ) + Value 3 (0x08 = 8 )

1+2+4+8 = 15 --> Converted = 0x0f ( i need the 0x0f )

How to do that? Thanks

Edited April 29, 2013 by MyEarth

[Melba23]

MyEarth,

I suggest you do this:

; Declare the array like this:
Global $aArray[8] = [0x01, 0x02, 0x04, 0x08, 0x10, 0x20, 0x40, 0x80]

; And then change the $Button Case to read:
Case $Button
    Local $Value = "", $FinalHex = 0
    For $i = 0 To $NumberExample - 1
        If GUICtrlRead($Checkbox_[$i]) = $GUI_CHECKED Then
            $FinalHex += $aArray[$i]
        EndIf
    Next
    MsgBox(0, 0, "0x" & Hex($FinalHex, 2))

That gives me the correct result.

M23

[MyEarth]

Was so "simple"?

Thanks Melba, yes it's correct