Stay in front, email

[Luke 0]

With email newsletters or news summaries, it's nice to be able to click links as you read and continue uninterrupted while the Web pages load in the background. The spoilsport is a browser that pops to the front with every link clicked. Here's one workaround for PocoMail. Similar solutions are probably doable for other email programs.

For those who read their mail in the preview pane, add a button to PocoMail's toolbar that toggles the "stay in front" flag for Poco's main window. The button could launch this PocoScript:

Execute "C:\Program Files\StayInFrontPM_Main.exe"

Where StayInFrontPM_Main.exe is the following AutoIt script or something like it:

; StayInFrontPM_Main
; Luke (M.B.), 2005-08
;
; Keeps Poco's main window in front.
;
; Suggested usage:
; Add a button to Poco's toolbar that launches this script.
; Click the button to start keeping Poco in front.
; Click it again, or close Poco, to stop.

Opt("WinTitleMatchMode", 3) ; 3=exact
Const $scripttitle = "StayInFrontPM 4griHUN4"

If Not WinExists("PocoMail") Then
    MsgBox(48, @ScriptName, "PocoMail is not running")
    Exit
EndIf
    
If WinExists($scripttitle) Then
; The script has run; SetOnTop is set; unset it; quit StayInFront
    WinSetOnTop("PocoMail", "", 0)
    WinClose($scripttitle)
    Exit
EndIf

WinSetOnTop("PocoMail", "", 1)
AutoItWinSetTitle($scripttitle)
While WinExists("PocoMail")
    Sleep(3000)
WEnd

Those who, like me, read email in the message pane, as opposed to the preview pane, could substitute the following AutoIt script. The text in the message pane's title bar is unpredictable.

; StayInFrontPM_Msg
; Luke (M.B.), 2005-08
;
; Keeps Poco's message pane in front.
;
; Suggested usage:
; Add a button to Poco's toolbar that launches this script.
; Click the button to start keeping the message pane in front.
; Click it again, or close Poco, to stop.

Opt("WinTitleMatchMode", 4) ; 4=advanced
Const $scripttitle = "StayInFrontPM 4griHUN4"

; If an instance of this script is already running, close it and exit
If WinExists($scripttitle) Then
    WinClose($scripttitle)
    Exit
EndIf
AutoItWinSetTitle($scripttitle)

While WinExists("PocoMail")
    If WinExists("classname=TFrmMsg") Then
        WinActivate("last")
    EndIf
    Sleep(1000)
WEnd

Reference:

The PocoMail FAQ - Assigning a script to a button and keyboard shortcut

http://www.jdfsoftware.com/pocofaq/poco-sc...ingbuttons.html