Refresh Combo Box after first combo box option changes

[cookiemonster]

Ive got two combo box's, the first one you select the folder, and the second one lists all the folders within that folder for you to select from.

How can I get the second combo to rescan when I change select of the first one?

This is what ive got at the moment, I just need it to update the list if I change my folder selected in the first combo.

$Folder = GUICtrlCreateCombo("C:\Folder1", 142, 122, 435, 22, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "C:\Folder2")

Local $folderselector = GUICtrlRead($Folder)


If $folderselector = "C:\Folder1" Then
Local $FileList = _FileListToArray("C:\Folder1")
_ArrayDelete($FileList, 0)
$sFileList = _ArrayToString($FileList, "|")
Else
$folderselector = "C:\Folder2" Then
Local $FileList = _FileListToArray("C:\Folder2")
_ArrayDelete($FileList, 0)
$sFileList = _ArrayToString($FileList, "|")

EndIf

[cookiemonster]

ok so already found an issue with my code, updated it to this but still dunno how to refresh:

$Folder = GUICtrlCreateCombo("C:\Folder1", 142, 122, 435, 22, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "C:\Folder2")

Local $folderselector = GUICtrlRead($Folder)


If $folderselector = "C:\Folder1" Then
Local $FileList = _FileListToArray("C:\Folder1")
_ArrayDelete($FileList, 0)
$sFileList = _ArrayToString($FileList, "|")
Else
Local $FileList = _FileListToArray("C:\Folder2")
_ArrayDelete($FileList, 0)
$sFileList = _ArrayToString($FileList, "|")

EndIf

[Melba23]

cookiemonster,

Just wait until there is a selection in the first combo and then update the second:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <Constants.au3>
#include <ComboConstants.au3>
#include <Array.au3>
#include <File.au3>

Global $sAutoItDir = StringLeft(@AutoItExe, StringInStr(@AutoItExe, "\", Default, -1))
If StringRight($sAutoItDir, 5) = "beta\" Then
    $sAutoItDir = StringTrimRight($sAutoItDir, 5)
EndIf

$hGUI = GUICreate("Test", 500, 500)


$cCombo_1 = GUICtrlCreateCombo("", 10, 50, 230, 20, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL, $WS_VSCROLL))

$cCombo_2 = GUICtrlCreateCombo("", 260, 50, 230, 20, BitOR($CBS_DROPDOWNLIST, $CBS_AUTOHSCROLL, $WS_VSCROLL))

GUISetState()

$aList_1 = _FileListToArray($sAutoItDir, "*", 2)
GUICtrlSetData($cCombo_1, "|" & _ArrayToString($aList_1, "|", 1))

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo_1
            $sPath = $sAutoItDir & "\" & GUICtrlRead($cCombo_1)
            $aList_2 = _FileListToArray($sPath, "*", 2)
            GUICtrlSetData($cCombo_2, "|" & _ArrayToString($aList_2, "|", 1))
    EndSwitch

WEnd

Does that do the trick?

 

M23

[cookiemonster]

Yep, but unfortunately every things just changed and I dont need to do that now, but many thanks, im sure that will come in handy in the future!!