Text color in label

[mohammadezazi]

It is my code:

Local $gui = GUICreate("", 617, 170, -1,-1,$WS_POPUP)   
   GUISetBkColor(0x3399FF)      
   GUISetFont(9, 400, -1, "Tahoma")
   GUICtrlCreateLabel("Some text", 2, 2, 613, 140,$SS_WHITERECT) 
   GUICtrlSetColor(-1, 0x000000) ; Red
   $taiid = GUICtrlCreateButton("OK", 50, 145, 60, 20)
   $cancel = GUICtrlCreateButton("Cansel", 500, 145, 60, 20)        
   GUISetState(@SW_SHOW)   
   Do
      Local $msg = GUIGetMsg()
             Switch $msg
                       case $taiid
                                 MsgBox(0,"OK","OK")
                       Case $cancel, $GUI_EVENT_CLOSE
                                 GUIDelete($gui)
                                 ExitLoop
            EndSwitch        
   Until 0

Why the text does not be shown?

Or how  can define label's text color?

I want to the text color remain Red. and the window must be in this format.

Edited August 8, 2013 by mohammadezazi

[Melba23]

mohammadezazi,

The FRAME and RECT styles for labels do not allow text within the control. You need to create another label above these controls if you want to display text.

But in this case, why not just colour the background of the label itself:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <StaticConstants.au3>

Local $gui = GUICreate("", 617, 170, -1, -1, $WS_POPUP)
GUISetBkColor(0x3399FF)
GUISetFont(9, 400, -1, "Tahoma")

GUICtrlCreateLabel("Some text", 2, 2, 613, 140)
GUICtrlSetColor(-1, 0xFF0000) ; Red
GUICtrlSetBkColor(-1, 0xFFFFFF)


$taiid = GUICtrlCreateButton("OK", 50, 145, 60, 20)
$cancel = GUICtrlCreateButton("Cancel", 500, 145, 60, 20)

GUISetState(@SW_SHOW)

Do
    Local $msg = GUIGetMsg()
    Switch $msg
        Case $taiid
            MsgBox(0, "OK", "OK")
        Case $cancel, $GUI_EVENT_CLOSE
            GUIDelete($gui)
            ExitLoop
    EndSwitch
Until 0

M23

[mohammadezazi]

Thank you very much.