Inputbox - disallow space

[legend 16]

Hello.

I'm unsure how this would be done, I want to make a inputbox, but I don't want to allow spaces, is that possible?

InputBox("input", "type-something-but-dont-allow-space")

 

[Melba23 3,456]

legend,

You will have to create your own GUI with an input contol and remove the spaces yourself like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Test", 500, 500)
$cInput = GUICtrlCreateInput("", 10,  20, 300, 20)
GuiSetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord

    If $iIDFrom = $cInput And $iCode = $EN_CHANGE Then

        $sInput = GUICtrlRead($cInput)
        $sInput = StringReplace($sInput, " ", "")
        GUICtrlSetData($cInput, $sInput)

    EndIf

EndFunc   ;==>_WM_COMMAND

All clear?

 

M23

[MHz 80]

Do
    $result = InputBox('title', 'Add text with no whitespace', '')
    If @error Then Exit 1
Until StringInStr($result, ' ') = False

Keep looping until you get the result that you want. Of course you can be more descriptive then my example with a MsgBox or such as a warning.

[legend 16]

thank you both just what i need