listbox scroll down by click Button

[LastSoul]

hey guys

i tried to scroll down the select item in listbox but its select more then one item .

just need to scroll down every time i click the Button .

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <array.au3>


$Form1 = GUICreate("Form1", 254, 233, 516, 270)
$List1 = GUICtrlCreateList("", 16, 8, 217, 149, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL)) ; BitOR style taken from help file
$sItems = "1|2|3|4|5" ; To simplify, no txt list. Just this one for testing purposes.
GUICtrlSetData($List1, $sItems)
_GUICtrlListBox_SetSel($List1,0) ; Set position 1 (which is the 2nd in list) as default
$Button1 = GUICtrlCreateButton("Button1", 80, 176, 75, 25)
GUISetState(@SW_SHOW)


Local $aaa
Local $sss


While 1
    $aaa = GUIGetMsg()
    Select
        Case $aaa = $GUI_EVENT_CLOSE
            ExitLoop
        Case $aaa = $Button1
            $selItems = _GUICtrlListBox_GetSelItemsText($List1)
$sss = $sss + 1
_GUICtrlListBox_SetSel($List1, $sss); Read the selected item characteristics to an array
            MsgBox(4160, "Information", "Item Selected: " & $selItems[1]) ; $selItems[1] cooresponds to the the selected text value in this array
    EndSelect
WEnd

 

[BrewManNH]

You never deselect the first one before moving down to the next selection. You have a MultiSelect Listbox, so you can have multiple items selected. Try this.

#include <ButtonConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <WindowsConstants.au3>
#include <array.au3>


$Form1 = GUICreate("Form1", 254, 233, 516, 270)
$List1 = GUICtrlCreateList("", 16, 8, 217, 149, BitOR($LBS_STANDARD, $LBS_EXTENDEDSEL)) ; BitOR style taken from help file
$sItems = "1|2|3|4|5" ; To simplify, no txt list. Just this one for testing purposes.
GUICtrlSetData($List1, $sItems)
_GUICtrlListBox_SetSel($List1, 0) ; Set position 1 (which is the 2nd in list) as default
$Button1 = GUICtrlCreateButton("Button1", 80, 176, 75, 25)
GUISetState(@SW_SHOW)


Local $aaa, $Selected
Local $sss = 0


While 1
    $aaa = GUIGetMsg()
    Select
        Case $aaa = $GUI_EVENT_CLOSE
            ExitLoop
        Case $aaa = $Button1
            $selItems = _GUICtrlListBox_GetSelItemsText($List1)
            $Selected = _GUICtrlListBox_GetSelItems($List1)
            _GUICtrlListBox_SetSel($List1, $Selected[1], False)
            $sss = $sss + 1
            If $sss = _GUICtrlListBox_GetCount($List1) Then $sss = 0
            _GUICtrlListBox_SetSel($List1, $sss); Read the selected item characteristics to an array
            MsgBox(4160, "Information", "Item Selected: " & $selItems[1]) ; $selItems[1] cooresponds to the the selected text value in this array
    EndSelect
WEnd

You'll see that I also fixed an issue you would have had even if this had worked as intended, you counted up and selected the next item in the list, but you never took into account that eventually you'd end up at the bottom of the list and your script would have crashed when you ran out of items. I made it so that it wraps back to the first item in the list instead of crashing. If you wanted it to stay at the last item in the list after you've scrolled down to it, change this line.

; From this
If $sss = _GUICtrlListBox_GetCount($List1) Then $sss = 0
; To this
If $sss = _GUICtrlListBox_GetCount($List1) Then $sss = _GUICtrlListBox_GetCount($List1) - 1

[TheSaint]

OOPS, too slow ... should have guessed BrewManNH would be on the job.

You need to get the selected index first, every time you click the button, then increment it by one.

That requires the following to be in your Button code

$iIndex = _GUICtrlListBox_GetCurSel($hWnd)

$iIndex = $iIndex + 1

_GUICtrlListBox_SetCurSel($hWnd, $iIndex)

You should also use

_GUICtrlListBox_GetCount($hWnd)

so that you can modify what happens when you get to the end of your list.

Edited August 24, 2013 by TheSaint