Help with simple function for window toggling

[sackjarrow]

Hi!

I'm very stuck with this function.

I would like a function that when I press a certain hotkey minimizes the currently active window. When I press the same certain hotkey again I want the previously minimized window to maximize again.

So far I've got:

hotkeyset("{numpad1}", "_end")
hotkeyset("{numpad0}", "_mini")

while 1
   sleep(50)
   WEnd
   
Func _mini()
local $wintitle = wingettitle("[active]")
   if WinActive($wintitle) then
   Winsetstate($wintitle, "", @SW_MINIMIZE)
   Else
   Winsetstate($wintitle, "", @SW_MAXIMIZE)
   EndIf
   EndFunc

 Func _end()
      Exit
   EndFunc

However the local $wintitle = wingettitle("[active]") is incorrectly placed in the script such that the script always minimizes the currently active window (imagine I have several windows open) and of course no maximize. I simply can't work out the logic for this to work. 

[Melba23]

sackjarrow,

Store the handle of the GUI you minimized and then use it to restore:

HotKeySet("{numpad1}", "_end")
HotKeySet("{numpad0}", "_mini")

; Flag to hold the handle of the GUI
Global $hActive_Last = 0

While 1
    Sleep(10)
WEnd

Func _mini()
    ; Get current active handle
    Local $hActive_Curr = WinGetHandle("[ACTIVE]")
    ; If nothing minimised at present
    If $hActive_Last = 0 Then
        ; Minimise the GUI
        WinSetState($hActive_Curr, "", @SW_MINIMIZE)
        ; Store the handle
        $hActive_Last = $hActive_Curr
    Else
        ; Restore the GUI
        WinSetState($hActive_Last, "", @SW_RESTORE)
        ; Clear the flag
        $hActive_Last = 0
    EndIf
EndFunc   ;==>_mini

Func _end()
    Exit
EndFunc   ;==>_end

All clear?

M23

[sackjarrow]

Yes that is brilliant! Thank you so much