Config GUI - Doubts

[GordonFreeman]

Hi, i want create a Config GUI to my program like that:

I have few doubts:

1. When i click in some treview button i need make to destroy all right controlls and create the specified for the "class" or have another better way?

2. Who controll can i use to make this "line" near TreeView or OK

[Melba23]

GordonFreeman,

Personally I would create all the required controls at the beginning of the script and then show/hide them like this:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <Constants.au3>

$iSelections = 3

Global $aSections[$iSelections + 2]

$hGUI = GUICreate("Test", 500, 500)

$cCombo = GUICtrlCreateCombo("", 10, 10, 100, 20)
GUICtrlSetData($cCombo, "1|2|3")

; Create a line
GUICtrlCreateLabel("", 10, 40, 480, 1)
GUICtrlSetBkColor(-1, 0)

; Controls for 1
$aSections[1] = GUICtrlCreateDummy()

$cEdit_1 = GUICtrlCreateEdit("Edit 1", 10, 100, 480, 300)
GUICtrlSetBkColor(-1, 0xFFCCCC)
$cButton_1 = GUICtrlCreateButton("Button 1", 10, 460, 80, 30)

; Controls for 2
$aSections[2] = GUICtrlCreateDummy()

$cEdit_2 = GUICtrlCreateEdit("Edit 2", 10, 100, 480, 300)
GUICtrlSetBkColor(-1, 0xCCFFCC)
$cButton_2 = GUICtrlCreateButton("Button 2", 10, 460, 80, 30)

; Controls for 3
$aSections[3] = GUICtrlCreateDummy()

$cEdit_3 = GUICtrlCreateEdit("Edit 3", 10, 100, 480, 300)
GUICtrlSetBkColor(-1, 0xCCCCFF)
$cButton_3 = GUICtrlCreateButton("Button 3", 10, 460, 80, 30)

; And close this section
$aSections[$iSelections + 1] = GUICtrlCreateDummy()

; Hide all controls
_Hide_All()

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cCombo
            ; Hide all controls
            _Hide_All()
            ; Show the controls for this selection
            _Show_Section(GUICtrlRead($cCombo))
    EndSwitch

WEnd

Func _Show_Section($iIndex)
    ; Loop through the controls in this section
    For $i = $aSections[$iIndex] To $aSections[$iIndex + 1]
        GUICtrlSetState($i, $GUI_SHOW)
    Next
EndFunc

Func _Hide_All()
    ; Loop through all controls
    For $i = $aSections[1] To $aSections[$iSelections + 1]
        GUICtrlSetState($i, $GUI_HIDE)
    Next
EndFunc

Please ask if anything is not clear.

M23

[GordonFreeman]

Exactly i want, thanks melba!