Is it possible to stop and restart a while loop?

[gottygolly]

I'm just messing around right now and I can't figure out how to stop the while loop and restart it again. Actually I can't even get it to stop for some reason.

Objective: Make it so when you press start the 2 top buttons flash back and forth and when you press stop it stops them.

Here's the code:

#include <GUIConstantsEx.au3>
$gui = GUICreate("",200,100)

$b1 = GUICtrlCreateButton("Button 1",0,0,100,30)
$b2 = GUICtrlCreateButton("Button 2",100,0,100,30)
$start = GUICtrlCreateButton("Start",0,50,100,30)
$stop = GUICtrlCreateButton("Stop",100,50,100,30)
GUICtrlSetState($b1,$GUI_DISABLE)

GUISetState()

while 1
   $msg = GUIGetMsg(1)
   Switch $msg[1]
   Case $gui
      Switch $msg[0]
      Case -3
         Exit
      Case $start
         while 1
            If  $msg = $stop Then ExitLoop
         GUICtrlSetState($b1,$GUI_DISABLE)
         Sleep(100)
         GUICtrlSetState($b1,$GUI_ENABLE)
         Sleep(100)
         GUICtrlSetState($b2,$GUI_DISABLE)
         Sleep(100)
         GUICtrlSetState($b2,$GUI_ENABLE)
         Sleep(100)
      WEnd
      EndSwitch
   EndSwitch
WEnd
 

Thanks in advance

Edited March 13, 2014 by gottygolly

[Melba23]

gottygolly,

I presume the idea is to have a random "enabled" button when you stop - so this should work:

expandcollapse popup

#include <GUIConstantsEx.au3>
$gui = GUICreate("", 200, 100)

$b1 = GUICtrlCreateButton("Button 1", 0, 0, 100, 30)
$b2 = GUICtrlCreateButton("Button 2", 100, 0, 100, 30)
$start = GUICtrlCreateButton("Start", 0, 50, 100, 30)
$stop = GUICtrlCreateButton("Stop", 100, 50, 100, 30)
GUICtrlSetState($b1, $GUI_DISABLE)

GUISetState()

While 1
    $msg = GUIGetMsg(1)
    Switch $msg[1]
        Case $gui
            Switch $msg[0]
                Case $GUI_EVENT_CLOSE
                    Exit
                Case $start
                    While 1
                        GUICtrlSetState($b1, $GUI_DISABLE)
                        GUICtrlSetState($b2, $GUI_ENABLE)
                        If _Check(200) Then ExitLoop
                        GUICtrlSetState($b1, $GUI_ENABLE)
                        GUICtrlSetState($b2, $GUI_DISABLE)
                        If _Check(200) Then ExitLoop
                    WEnd
            EndSwitch
    EndSwitch
WEnd

Func _Check($iDelay)
    $nBegin = TimerInit()
    Do
        Switch GUIGetMsg()
            Case $stop
                Return 1
        EndSwitch
    Until TimerDiff($nBegin) > $iDelay
    Return 0
EndFunc

M23

[gottygolly]

Thanks for quick reply Melba and the code works like I wanted it to

[czardas]

Altthough not specific to this situation, the following related post may also be of interest.