Translating a GUID to string

[perfaram]

Hi all !

I came across this : '?do=embed' frameborder='0' data-embedContent>>

And I was wondering about reverting the created GUID to the original string. Is that possible ?

I think yes, because it only uses a StringRegExpReplace, but I'm not sure how to do it 

Thx in advance !

PS : This may help

[mikell]

$g = CreateGUIDFromString('A GUID string.')
MsgBox(0, '', $g)

$s = BinaryToString("0x" & StringRegExpReplace($g, "[{}-]", ""))
MsgBox(0, '', $s)

Func CreateGUIDFromString($sString)
    Return StringRegExpReplace(StringToBinary($sString) & _ 
    "0000000000000000000000000000000000", "..(.{8})(.{4})(.{4})(.{4})(.{12}).*", "\{$1-$2-$3-$4-$5\}")
EndFunc

?

[UEZ]

Try this:

Func CreateStringFromGUID($sGUID)
    Local $sHex = StringRegExpReplace($sGUID, "[{|\-|}]", "")
    If @error Then Return SetError(1, 0, 0)
    If Mod(StringLen($sHex), 2) Then Return SetError(2, 0, 0)
    Local $aChars = StringRegExp($sHex, ".{2}", 3)
    If @error Then Return SetError(2, 0, 0)
    Local $i, $sReturn, $sChar
    For $i = 0 To UBound($aChars) - 1
        If Not Int($aChars[$i]) Then ExitLoop
        $sReturn &= Chr(Dec($aChars[$i]))
    Next
    Return $sReturn
EndFunc

Br,

UEZ

[perfaram]

It works, but it is heavily truncated : 

MsgBox(32, "", CreateStringFromGUID(CreateGUIDFromString('Some very simple string.')))
Func CreateGUIDFromString($sString)
    Return StringRegExpReplace(StringToBinary($sString) & "0000000000000000000000000000000000", "..(.{8})(.{4})(.{4})(.{4})(.{12}).*", "\{$1-$2-$3-$4-$5\}")
EndFunc ;==>CreateGUIDFromString

Func CreateStringFromGUID($sGUID)
    Local $sHex = StringRegExpReplace($sGUID, "[{|\-|}]", "")
    If @error Then Return SetError(1, 0, 0)
    If Mod(StringLen($sHex), 2) Then Return SetError(2, 0, 0)
    Local $aChars = StringRegExp($sHex, ".{2}", 3)
    If @error Then Return SetError(2, 0, 0)
    Local $i, $sReturn, $sChar
    For $i = 0 To UBound($aChars) - 1
        If Not Int($aChars[$i]) Then ExitLoop
        $sReturn &= Chr(Dec($aChars[$i]))
    Next
    Return $sReturn
EndFunc

Will return 'Some very simple' instead of 'Some very simple string.'. Dunno if it's normal, though 

[UEZ]

The function is limited to 16 chars. That means the encoded GUID is truncated.

Br,

UEZ

[mikell]

UEZ,

expandcollapse popup

$g = CreateGUIDFromString('A GUID string.')
;MsgBox(0, '', $g)

$hTimer = TimerInit()
For $i = 1 to 100
  $s = CreateStringFromGUID1($g) 
Next
$fDiff1 = TimerDiff($hTimer)
;MsgBox(0, '', $s)

$hTimer = TimerInit()
For $i = 1 to 100
  $s = CreateStringFromGUID2($g)
Next
$fDiff2 = TimerDiff($hTimer)
;MsgBox(0, '', $s)

MsgBox(0, '', $fDiff1 &@crlf& $fDiff2)

;=============================================
Func CreateStringFromGUID1($sGUID)
    Local $sHex = StringRegExpReplace($sGUID, "[{}-]", "")
    If @error Then Return SetError(1, 0, 0)
    If Mod(StringLen($sHex), 2) Then Return SetError(2, 0, 0)
    $sReturn = BinaryToString("0x" & $sHex)
    Return $sReturn
EndFunc   

Func CreateStringFromGUID2($sGUID)
    Local $sHex = StringRegExpReplace($sGUID, "[{|\-|}]", "")
    If @error Then Return SetError(1, 0, 0)
    If Mod(StringLen($sHex), 2) Then Return SetError(2, 0, 0)
    Local $aChars = StringRegExp($sHex, ".{2}", 3)
    If @error Then Return SetError(2, 0, 0)
    Local $i, $sReturn, $sChar
    For $i = 0 To UBound($aChars) - 1
        If Not Int($aChars[$i]) Then ExitLoop
        $sReturn &= Chr(Dec($aChars[$i]))
    Next
    Return $sReturn
EndFunc

Func CreateGUIDFromString($sString)
    Return StringRegExpReplace(StringToBinary($sString) & _ 
    "0000000000000000000000000000000000", "..(.{8})(.{4})(.{4})(.{4})(.{12}).*", "\{$1-$2-$3-$4-$5\}")
EndFunc

[UEZ]

Nice mikell 

I hacked my version in 5 minutes together and have to leave my pc afterwards. So I had no time for optimizations.

Br,

UEZ

[perfaram]

Thanks UEZ for your quick answer, and thanks mikell for the optimization