find oldest file(s) in directory

[memnon]

hello,

i need to find the oldest file(s) in directory to zip them away and delete them after.

I therefor tried to use Filegettime and _fileListToArray

Local $aFileList = _FileListToArray("d:tmptestold", "*.conf")

for $i=1 to $aFilelist[0]
        $FileTime=FileGetTime("d:tmptestold" & $aFilelist[$i], $FT_MODIFIED, 0)
        $FileX=$aFilelist[$i] & "," & $Filetime[0] & "," & $Filetime[1] & "," & $Filetime[2]
        Local $array2=StringSplit($fileX, ",")

       _ArrayDisplay($Array2, "$Array2")
next

so i get Filename,Year,Month,Day within $Array2

but how can i get that $Array2 (within the for-next loop) into a new Array and how can i "sort" the rows from oldest to newest then ?

someone with an idea for me ?

Edited June 12, 2014 by memnon

[Geir1983]

Create a two dimensional array where you have filename + timeinformation on every item. Then sort it using _ArraySort on the colum for time

[Danp2]

Here's a function that I use to retrieve the most recently modified file. You could use this as a starting point...

Func _GetLastFile($sPath, $sFileSpec, $lDirectory = False, $nStampType = 0)
    Local $aList, $sResult

    $sPath = AddBackslash($sPath)

    ; Get array of file / directory names
    $aList = _FileListToArray($sPath, $sFileSpec, _Iif($lDirectory, 2, 1))

    ; Create a suitably sized 2D array to hold the names and sizes - count in the [0][0] element
    Local $aName_Time[$aList[0] + 1][2] = [[$aList[0]]]

    ; Now loop through the original array
    For $i = 1 To $aList[0]
        ; Transfer the names to the [0] element
        $aName_Time[$i][0] = $sPath & $aList[$i]

        If $lDirectory And StringRight($aName_Time[$i][0], 1) = "\" Then
            ; remove trailing slash \
            $aName_Time[$i][0] = StringLeft($aName_Time[$i][0], StringLen($aName_Time[$i][0]) - 1)
        EndIf

        ; Get the requested time to put in the [1] element
        $aName_Time[$i][1] = FileGetTime($aName_Time[$i][0], $nStampType, 1)
    Next

    ; Sort array by modified time
    _ArraySort($aName_Time, 0, 1, 0, 1)

    ; Get name of file at the bottom of the list
    $sResult = $aName_Time[$aName_Time[0][0]][0]

    Return $sResult
EndFunc

[Geir1983]

Another example

#include <File.au3>
#include <array.au3>

Local $sSearchPath = "c:\test\"
Local $aFileList = _FileListToArray($sSearchPath, "*.*")
Local $aExtendedFileList[$aFileList[0]+1][2]

for $i=1 to $aFilelist[0]
    $aExtendedFileList[$i][0] = $aFileList[$i]
    $aExtendedFileList[$i][1] = FileGetTime($sSearchPath & $aFileList[$i] , $FT_MODIFIED, 1)
next

_ArraySort($aExtendedFileList, 0,0,0, 1)
_ArrayDisplay($aExtendedFileList, "$aFileList")

Edited June 12, 2014 by Geir1983

[memnon]

addbackslash ?

_Lif ?

[memnon]

thx very much Geir1983, works like a charm

[Danp2]

Func AddBackslash($sPath)
    If StringRight($sPath, 1) <> "\" Then
        $sPath &= '\'
    EndIf

    Return $sPath
EndFunc

_Iif is defined in Misc.au3

; #INDEX# =======================================================================================================================
; Title .........: Misc
; AutoIt Version : 3.3.7.20++
; Language ......: English
; Description ...: Functions that assist with Common Dialogs.
; Author(s) .....: Gary Frost, Florian Fida (Piccaso), Dale (Klaatu) Thompson, Valik, ezzetabi, Jon, Paul Campbell (PaulIA)
; Dll(s) ........: comdlg32.dll, user32.dll, kernel32.dll, advapi32.dll, gdi32.dll
; ===============================================================================================================================

[memnon]

thx Danp2

[BrewManNH]

_Iif doesn't exist any more, it was removed back in 3.3.9.6 in 2013. Use the ternary operator in its place.

[memnon]

a last question to Geir1983 - i dont understand the line

Local $aExtendedFileList[$aFileList[0]+1][2]

i have never seen a definition for an array like that before - what does [0]+1] [2] mean ?

[Danp2]

You are declaring an array where the size of the first dimension is determined by the value of $aFileList[0]+1.

[memnon]

got it now, man i´m stupid^^

thx danp2