ListView vertical scrollbar on the left-hand-side?

[orbs]

i may be missing the obvious here, but, any way of creating a ListView with the vertical scrollbar placed on the left-hand-side?

thanks for any hints...

[Melba23]

orbs,

As long as you do not mind reversing the whole ListView you can do this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView("Column 1", 10, 10, 489, 480, BitOr($LVS_SHOWSELALWAYS, $LVS_SINGLESEL), $WS_EX_LAYOUTRTL)
For $i = 1 To 100
    GUICtrlCreateListViewItem("Item " & $i, $cListView)
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

M23

[funkey]

Something like this?

[orbs]

@funkey, i can't see how is that helpful?

@Melba23, that's smart going RTL   i don't mind re-ordering the columns, but the columns are now justified to the right, i had to throw this in:

_GUICtrlListView_JustifyColumn($cListView, 0, 1)

so this code works great, thanks!

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ListViewConstants.au3>
#include <GuiListView.au3>

$hGUI = GUICreate("Test", 500, 500)

$cListView = GUICtrlCreateListView("Column 1", 10, 10, 489, 480, BitOR($LVS_SHOWSELALWAYS, $LVS_SINGLESEL), $WS_EX_LAYOUTRTL)
_GUICtrlListView_JustifyColumn($cListView, 0, 1)
_GUICtrlListView_SetColumnWidth($cListView, 0, 200)
For $i = 1 To 100
    GUICtrlCreateListViewItem("Item " & $i, $cListView)
Next

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

[Melba23]

orbs,

Glad it helped. Just out of interest, why do you want the scroll bar on the left?

M23

[orbs]

orbs,

Glad it helped. Just out of interest, why do you want the scroll bar on the left?

M23

 

i'm using the method you >once showed me - which, b.t.w, i'm grateful for - and i'm switching between a secondary ListView to a graphical presentation, which does not have a vertical scrollbar. so i need the vertical scrollbar on the primary ListView - but when it's on the normal right-hand-side, it makes the entire GUI somewhat unappealing. putting it on the left sorts this out quite well it seems.

[Melba23]

orbs,

Thanks for the explanation - I was wondering!

M23