StringRegExpReplace() versus _ArrayUnique()

[Iczer]

Is it possible to get string with unique sub-strings using one-line StringRegExpReplace()  pattern? In other words to replace StringSplit() - _ArrayUnique() - _ArrayToString() construction with some RegExp one-liner?

#include <Array.au3>
;
$sSomeString = "asd|asd|qqq|www|qqq|ddd|ggg|jjj"
ConsoleWrite($sSomeString&@crlf)
;
$aTempArray = StringSplit($sSomeString,"|",2)
$aTempArray = _ArrayUnique($aTempArray)
$sSomeString = _ArrayToString($aTempArray,"|",1)
;
ConsoleWrite($sSomeString&@crlf)

[mikell]

Yes, but the pattern construction depends a lot on the content of the substrings

$sSomeString = "bcd|as-d|as-d|-qqq|www|-qqq|ddd|ggg|jjj"
$ret = StringRegExpReplace($sSomeString, '(?<=^|\|)(.+\|)(?=.*\1.*)', '')
msgbox(0,"", $ret)

Edited August 7, 2014 by mikell

[jchd]

Yes, like this:

$sSomeString = "asd|asd|qqq|www|qqq|ddd|ggg|jjj|jjj"
ConsoleWrite($sSomeString & @LF)
$sSomeString = StringRegExpReplace($sSomeString, "(\b[^|]+)(\|)(?=(?:[^|]+\|)*\1(?:\||$))", "")
ConsoleWrite($sSomeString & @LF)

mikell,

Beware of dot* and boundaries!

$sSomeString = "bcd|as-d|as-d|-qqq|www|something-qqq|ddd|ggg|jjj"
$ret = StringRegExpReplace($sSomeString, '(?<=^|\|)(.+\|)(?=.*\1.*)', '')
msgbox(0,"", $ret)

[mikell]

jc,

That's precisely the reason why I wrote a warning about the substring content

Try your script on this string

$sSomeString = "bcd|as-d|as-d|-qqq|www|qqq|something-qqq|ddd|ggg|jjj"

Edit

before writing a regex, you have to know exactly what you're trying to match (Jan Goyvaerts)

Edited August 7, 2014 by mikell

[jchd]

The issue is not with the character class allowed but with subsequent prefixes of 1 capture:

$sSomeString = "asd|asd|qqq|www|qqq|ddd|ggg|asddd|jjj|jjj"
ConsoleWrite($sSomeString & @LF)
$sSomeString = StringRegExpReplace($sSomeString, "(\b[^|]+)(\|)(?=(?:[^|]+\|)*\1(?:\||$))", "")
ConsoleWrite($sSomeString & @LF)
$ret = StringRegExpReplace($sSomeString, '(?<=^|\|)(.+\|)(?=.*\1.*)', '')
ConsoleWrite($ret & @LF)

You discard "ddd|" because this capture as 1 also appears later in substring "asddd|" and matches the subpattern ".*1".

Of course the final pattern will have to cope with the actual allowable charset in real-wolrd substrings.

Edited August 7, 2014 by jchd

[mikell]

I agree, but if the substring starts with a W then the word boundary will not work any more, regardless of the character class used

Edit

$sSomeString = "asd|asd|-qqq|www|-qqq|ddd|ggg|dddas|asddd|jjj|jjj"
$ret = StringRegExpReplace($sSomeString, '(?<=^|\|)(.+)(\|)(?=.*(?<=\|)\1(?=\||$))', '')
ConsoleWrite($ret & @LF)

Edited August 7, 2014 by mikell

[jchd]

OK, but I was only adhering to the example format posted by the OP.