Flickering and Formats?

ReconX · October 6, 2014

Hi, I have created some input boxes and combo boxes and would like a label that mirrors them to be constantly updating as I type, like in real time. Although, I do have something similar going on, but it won't update until I move the mouse a bit. Even then, the text keeps flickering with every mouse movement. I also, would like to know how to set the format of text to have a hyphen after every five characters automatically. (Example; XXXXX-XXXXX-XXXXX)

Thanks in advanced. xD

Melba23 · October 6, 2014

ReconX,

I suggest you post the code you are using - anything we write is very unlikely to mirror your script and so would not be very helpful.

Does the formatted text display as part of the updated label or do you want the input boxes to format as you enter text? :huh:

M23

ReconX · October 6, 2014

I am just testing out some stuff so the code isn't all that organized, but.....

#include <GUIConstantsEx.au3>
#include <GUIConstants.au3>
#include <GDIPlus.au3>

$hGUI = GUICreate("Hello World", 700, 400)
GUISetState(@SW_SHOW)
$Exit = GUICtrlCreateButton("Exit", 600, 350, 75, 25)

;$Input1 = GUICtrlCreateInput("", 70, 20, 90, 20)
$Run1 = GUICtrlCreateButton("Update", 200, 350, 100, 50)

$Label1 = GUICtrlCreateLabel("Windows Version", 30, 20, 100, 20)
$Combo1 = GUICtrlCreateCombo("Make Selection", 140, 20, 200, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
GUICtrlSetData(-1, "Windows® XP Home Edition|test2|test3")

$Label2 = GUICtrlCreateLabel("Windows Version", 30, 50, 100, 20)
$Combo2 = GUICtrlCreateCombo("Make Selection", 140, 50, 200, 25, BitOR($CBS_DROPDOWN,$CBS_AUTOHSCROLL))
;GUICtrlSetData(-1, "Dell|test2|test3")
GUICtrlSetData(-1, "Dell|test2|test3")

$Label3 = GUICtrlCreateLabel("Windows Version", 30, 80, 100, 20)
$Input3 = GUICtrlCreateInput("", 140, 80, 100, 20)

While 1

    $nMsg = GUIGetMsg()
    
Select
    Case $nMsg = $GUI_EVENT_CLOSE or $nMsg = $Exit
    Exit
        ;Case $nMsg = $RUN1
        ;$user = GUICtrlRead($Input1)
        ;MsgBox(0,"User", $user )
        ;GUICtrlCreateLabel($user, 150, 100, 100, 20)

        Case $nMsg
        $OS_Name = GUICtrlRead($Combo1)
        GUICtrlCreateLabel($OS_Name, 50, 100, 200, 20)
        GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5) ; you need the Default to keep the font size the same

        $OEM_Name = GUICtrlRead($Combo2)
        If $OEM_Name = "Dell" Then
        EndIf
        
        $Key_Name = GUICtrlRead($Input3)
        GUICtrlCreateLabel($Key_Name, 50, 300, 200, 20)
        GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5) ; you need the Default to keep the font size the same
        
EndSelect
WEnd

The first List seems to update fine except for the flickering. The third box only updates if I move the mouse. If I type in an "A" i want it to display an "A" at the same time I typed it and so on. The second List was supposed to display an .PNG image depending on what was selected. Although I am thinking about scrapping it. I originally got the .png to display, but when I changed the image, it wouldn't go away.

I also would like the text typed in the third box to auto add a hyphen after every five characters that are typed. I apologize if I am asking to much, but thanks for the help.

Note: I am also getting rid of the update button.

Edited October 6, 2014 by ReconX

Melba23 · October 6, 2014

ReconX,

I have made a few changes which I hope are self-explanatory and which give you non-flickering labels:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <EditConstants.au3>

$hGUI = GUICreate("Hello World", 700, 400)

$Exit = GUICtrlCreateButton("Exit", 600, 350, 75, 25)

$Run1 = GUICtrlCreateButton("Update", 200, 350, 100, 50)

GUICtrlCreateLabel("Windows Version", 30, 20, 100, 20)
$Combo1 = GUICtrlCreateCombo("", 140, 20, 200, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
_GUICtrlComboBox_SetCueBanner($Combo1, "Make Selection") ; This now does not appear as a choice
GUICtrlSetData($Combo1, "Windows® XP Home Edition|test2|test3")

GUICtrlCreateLabel("Windows Version", 30, 50, 100, 20)
$Combo2 = GUICtrlCreateCombo("", 140, 50, 200, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
_GUICtrlComboBox_SetCueBanner($Combo2, "Make Selection")
GUICtrlSetData($Combo2, "Dell|test2|test3")

GUICtrlCreateLabel("Windows Version", 30, 80, 100, 20)
$Input3 = GUICtrlCreateInput("", 140, 80, 100, 20)
$cInput_Dummy = GUICtrlCreateDummy() ; This will fire when the input content changes

; Create the labels just once
$cLablel1 = GUICtrlCreateLabel("", 50, 120, 200, 20)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

$cLablel2 = GUICtrlCreateLabel("", 50, 150, 200, 20)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

$cLablel3 = GUICtrlCreateLabel("", 50, 180, 200, 20)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

GUISetState(@SW_SHOW)

; Register the message to look for changes to the input content
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $Exit
            Exit
        Case $Combo1
            GUICtrlSetData($cLablel1, GUICtrlRead($Combo1)) ; Update the label only when the combo is actioned
        Case $Combo2
            GUICtrlSetData($cLablel2, GUICtrlRead($Combo2))
        Case $cInput_Dummy
            GUICtrlSetData($cLablel3, GUICtrlRead($Input3)) ; Update the label only when the input content changes
    EndSwitch
WEnd

; The message we registered above
Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)
    ; Get the ControlID and the message value
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord
    ; If it was the input being changed
    If $iIDFrom = $Input3 And $iCode = $EN_CHANGE Then
        ; Add the dashes every 5 characters
        GUICtrlSetData($Input3, StringRegExpReplace(StringReplace(GUICtrlRead($Input3), "-", ""), "(.{5})", "$1-"))
        ; Fire the dummy control
    GUICtrlSendToDummy($cInput_Dummy)
    EndIf
EndFunc ;==>_WM_COMMAND

Please ask if you have any questions.

M23

P.S. I now see your edit re the formatting - just wait a bit.

Edit: Now added.

Edited October 7, 2014 by Melba23
Copy/Paste error

ReconX · October 6, 2014

Thank you very much Melba. I do have other questions tho. I did just test the code and it is exactly what I wanted. Although, is there a way to overcome when hitting the backspace in the third box, it will delete the hyphen as well? It stops at the hyphen and you would have to skip over it in order to delete the rest of the text. I did try to configure it myself with no luck. Also, is there a tutorial that would show me how to display an image such as a .png when I select a certain item in the first list box? I want a 300 x 75 px background to display behind the text when I select "test2", and when I select "test3" that background would be the same size although change to a different .png.

Also, the last character has a dash after it as well. I guess what I am looking for is inputting windows keys into the box. XXXXX-XXXXX-XXXXX-XXXXX-XXXXX.

Edited October 6, 2014 by ReconX

Melba23 · October 7, 2014

ReconX,

Would Sir like fries with that?

Take a look at this - I think it meets your requirements - although not in quite the way you might have imagined it:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <EditConstants.au3>

Global $aInput[5], $iIndex = 0

$hGUI = GUICreate("Hello World", 700, 400)

$Exit = GUICtrlCreateButton("Exit", 600, 350, 75, 25)

$Run1 = GUICtrlCreateButton("Update", 200, 350, 100, 50)

GUICtrlCreateLabel("Windows Version", 30, 20, 100, 20)
$Combo1 = GUICtrlCreateCombo("", 140, 20, 200, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
_GUICtrlComboBox_SetCueBanner($Combo1, "Make Selection") ; This now does not appear as a choice
GUICtrlSetData($Combo1, "Windows® XP Home Edition|test2|test3")

GUICtrlCreateLabel("Windows Version", 30, 50, 100, 20)
$Combo2 = GUICtrlCreateCombo("", 140, 50, 200, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
_GUICtrlComboBox_SetCueBanner($Combo2, "Make Selection")
GUICtrlSetData($Combo2, "Dell|test2|test3")

GUICtrlCreateLabel("Windows Version", 30, 80, 100, 20)
For $i = 0 To 4
    $aInput[$i] = GUICtrlCreateInput("", 140 + (70 * $i), 80, 50, 20)
    If $i > 0 Then GUICtrlSetState(-1, $GUI_DISABLE)
    If $i < 4 Then
        GUICtrlCreateLabel("-", 195 + (70 * $i), 70, 20, 20)
        GUICtrlSetFont(-1, 24)
    EndIf
Next
$cInput_Dummy = GUICtrlCreateDummy() ; This will fire when the input content changes

; Create the controls just once
$cLabel1 = GUICtrlCreateLabel("", 40, 140, 300, 75) ; Here you would want a Pic control

$cLabel2 = GUICtrlCreateLabel("", 50, 150, 200, 20)
GUICtrlSetBkColor($cLabel2, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

$cLabel3 = GUICtrlCreateLabel("", 50, 180, 200, 20)
GUICtrlSetBkColor($cLabel3, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

GUISetState(@SW_SHOW)

; Register the message to look for changes to the input content or focus
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        
        Case $GUI_EVENT_CLOSE, $Exit
            Exit
            
        Case $Combo1
            Switch GUICtrlRead($Combo1)
                Case "Windows® XP Home Edition"
                    GUICtrlSetBkColor($cLabel1, 0xFFCCCC) ; Here you would use GUICtrlSetImage to load the image into the Pic control
                Case "test2"
                    GUICtrlSetBkColor($cLabel1, 0xCCFFCC)
                Case "test3"
                    GUICtrlSetBkColor($cLabel1, 0xCCCCFF)
            EndSwitch

        Case $Combo2
            GUICtrlSetData($cLabel2, GUICtrlRead($Combo2))
            
        Case $cInput_Dummy
            $sKey = ""
            For $i = 0 To 4
                ; Read the input
                $sInput = GUICtrlRead($aInput[$i])
                ; Do we add a dash (only if 5 digits and not the final input)
                $sDash = ( (StringLen($sInput) = 5 And $i < 4) ? ("-") : ("") )
                $sKey &=  $sInput & $sDash
            Next
            GUICtrlSetData($cLabel3, $sKey) ; Update the label only when the input content changes
            
    EndSwitch

WEnd

; The message we registered above
Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    ; Get the ControlID and the message value
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord

    Switch $iCode
        Case $EN_CHANGE
            If $iIndex = 4 Then
                ; Limit to 5 chars
                GUICtrlSetData($aInput[4], StringLeft(GUICtrlRead($aInput[4]), 5))
            Else
                ; If 5 chars entered
                If StringLen(GUICtrlRead($aInput[$iIndex])) = 5 Then
                    ; Move to next input
                    $iIndex += 1
                    GUICtrlSetState($aInput[$iIndex], BitOr($GUI_ENABLE, $GUI_FOCUS))
                EndIf
            EndIf
            ; Fire the dummy control
            GUICtrlSendToDummy($cInput_Dummy)

        Case $EN_SETFOCUS
            ; Check which input has focus
            For $i = 0 To 4
                If $iIDFrom = $aInput[$i] Then
                    ; Set index to this input
                    $iIndex = $i
                    ExitLoop
                EndIf
            Next
            ; Blank and disable all subsequent inputs
            For $i = $iIndex + 1 To 4
                GUICtrlSetData($aInput[$i], "")
                GUICtrlSetState($aInput[$i], $GUI_DISABLE)
            Next

    EndSwitch

EndFunc ;==>_WM_COMMAND

Please ask if you have any questions.

M23

Melba23 · October 7, 2014

ReconX,

An updated version which makes using {BACKSPACE} easier:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <GuiComboBox.au3>
#include <EditConstants.au3>

Global $aInput[5], $iIndex = 0

$hGUI = GUICreate("Hello World", 700, 400)

$Exit = GUICtrlCreateButton("Exit", 600, 350, 75, 25)

$Run1 = GUICtrlCreateButton("Update", 200, 350, 100, 50)

GUICtrlCreateLabel("Windows Version", 30, 20, 100, 20)
$Combo1 = GUICtrlCreateCombo("", 140, 20, 200, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
_GUICtrlComboBox_SetCueBanner($Combo1, "Make Selection") ; This now does not appear as a choice
GUICtrlSetData($Combo1, "Windows® XP Home Edition|test2|test3")

GUICtrlCreateLabel("Windows Version", 30, 50, 100, 20)
$Combo2 = GUICtrlCreateCombo("", 140, 50, 200, 25, BitOR($CBS_DROPDOWN, $CBS_AUTOHSCROLL))
_GUICtrlComboBox_SetCueBanner($Combo2, "Make Selection")
GUICtrlSetData($Combo2, "Dell|test2|test3")

GUICtrlCreateLabel("Windows Version", 30, 80, 100, 20)
For $i = 0 To 4
    $aInput[$i] = GUICtrlCreateInput("", 140 + (70 * $i), 80, 50, 20)
    If $i > 0 Then GUICtrlSetState(-1, $GUI_DISABLE)
    If $i < 4 Then
        GUICtrlCreateLabel("-", 195 + (70 * $i), 70, 20, 20)
        GUICtrlSetFont(-1, 24)
    EndIf
Next
$cInput_Dummy = GUICtrlCreateDummy() ; This will fire when the input content changes

; Create the controls just once
$cLabel1 = GUICtrlCreateLabel("", 40, 140, 300, 75) ; Here you would want a Pic control

$cLabel2 = GUICtrlCreateLabel("", 50, 150, 200, 20)
GUICtrlSetBkColor($cLabel2, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

$cLabel3 = GUICtrlCreateLabel("", 50, 180, 200, 20)
GUICtrlSetBkColor($cLabel3, $GUI_BKCOLOR_TRANSPARENT)
GUICtrlSetFont(-1, 10, 600, Default, "Franklin Gothic Book", 5)

GUISetState(@SW_SHOW)

; Register the message to look for changes to the input content or focus
GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()

        Case $GUI_EVENT_CLOSE, $Exit
            Exit

        Case $Combo1
            Switch GUICtrlRead($Combo1)
                Case "Windows® XP Home Edition"
                    GUICtrlSetBkColor($cLabel1, 0xFFCCCC) ; Here you would use GUICtrlSetImage to load the image into the Pic control
                Case "test2"
                    GUICtrlSetBkColor($cLabel1, 0xCCFFCC)
                Case "test3"
                    GUICtrlSetBkColor($cLabel1, 0xCCCCFF)
            EndSwitch

        Case $Combo2
            GUICtrlSetData($cLabel2, GUICtrlRead($Combo2))

        Case $cInput_Dummy
            $sKey = ""
            For $i = 0 To 4
                ; Read the input
                $sInput = GUICtrlRead($aInput[$i])
                ; Do we add a dash (only if 5 digits and not the final input)
                $sDash = ( (StringLen($sInput) = 5 And $i < 4) ? ("-") : ("") )
                $sKey &=  $sInput & $sDash
            Next
            GUICtrlSetData($cLabel3, $sKey) ; Update the label only when the input content changes

    EndSwitch

WEnd

; The message we registered above
Func _WM_COMMAND($hWnd, $iMsg, $wParam, $lParam)

    ; Get the ControlID and the message value
    Local $iIDFrom = BitAND($wParam, 0xFFFF);LoWord
    Local $iCode = BitShift($wParam, 16) ;HiWord

    Switch $iCode
        Case $EN_CHANGE
            Switch $iIndex
                Case 0
                    _CheckFull()
                Case 1 To 3
                    $iRet = _CheckFull()
                    If Not $iRet Then _CheckEmpty()
                Case 4
                    ; Limit to 5 chars
                    GUICtrlSetData($aInput[4], StringLeft(GUICtrlRead($aInput[4]), 5))
                    _CheckEmpty()
            EndSwitch
            ; Fire the dummy control
            GUICtrlSendToDummy($cInput_Dummy)

        Case $EN_SETFOCUS
            ; Check which input has focus
            For $i = 0 To 4
                If $iIDFrom = $aInput[$i] Then
                    ; Set index to this input
                    $iIndex = $i
                    ExitLoop
                EndIf
            Next
            ; Blank and disable all subsequent inputs
            For $i = $iIndex + 1 To 4
                GUICtrlSetData($aInput[$i], "")
                GUICtrlSetState($aInput[$i], $GUI_DISABLE)
            Next

    EndSwitch

EndFunc ;==>_WM_COMMAND


Func _CheckEmpty()

    If StringLen(GUICtrlRead($aInput[$iIndex])) = 0 Then
        ; Disable input
        GUICtrlSetState($aInput[$iIndex], $GUI_DISABLE)
        ; Activate previous input
        $iIndex -= 1
        GUICtrlSetState($aInput[$iIndex], $GUI_FOCUS)
        ControlSend($hGUI, "", $aInput[$iIndex], "{END}")
    EndIf

EndFunc

Func _CheckFull()

    If StringLen(GUICtrlRead($aInput[$iIndex])) > 4 Then
        ; Limit to 5 chars
        GUICtrlSetData($aInput[$iIndex], StringLeft(GUICtrlRead($aInput[$iIndex]), 5))
        ; Move to next input
        $iIndex += 1
        GUICtrlSetState($aInput[$iIndex], BitOr($GUI_ENABLE, $GUI_FOCUS))
        Return 1
    EndIf
    Return 0

EndFunc

M23 Edited October 7, 2014 by Melba23
Even better version

ReconX · October 7, 2014

Thanks for all of your time Melba. I do have one last question tho, how did you learn so much about AutoIt? Was it a school or tutorials, or just trial and error. I see you helping all of these people on a daily basis, and I am very grateful. I too would like to one day help the AutoIt community.

Melba23 · October 7, 2014

ReconX,

I started coding at school some 45 years ago and it has been a hobby ever since. I found and liked AutoIt some 7 years ago and now I am retired I can come and play here when I am not flying or on the golf course. Besides helping out here keeps my little grey cells active and gets me out from under the wife's feet.

And please do help out if and when you can - the whole idea of the forum is so that everyone can see and learn and it is not just the longer-term members who have all the good ideas.

M23

ReconX · October 7, 2014

Thank you so much for your wisdom. I might just start calling you Gandolf.

Melba23 · October 7, 2014

ReconX,

I would not be worthy - Melba will do just fine.

M23

Sign In

Flickering and Formats?

Recommended Posts

ReconX

Melba23

ReconX

Melba23

ReconX

Melba23

Melba23

ReconX

Melba23

ReconX

Melba23

Create an account or sign in to comment

Create an account

Sign in

Recently Browsing 0 members

Browse

AutoIt Resources

Release

Beta