bug report

[zyzyeast]

Hi, when I'm using autoit v3.1 or v3.0, I find an error as following:

I use autoit for auto-installation. But for some softwares, which have the radio page during the installation, it'll be no response at the radio page.

This is my codes:

Run("fg165.exe")

WinWaitActive("Welcome")

ControlClick ( "Welcome", "&Next >", "Button1")

WinWaitActive("Software license")

ControlClick ( "Software license", "I &Agree", "Button1")

WinWaitActive("Choose Destination Location")

ControlClick ( "Choose Destination Location", "B&rowse...", "Button5")

WinWaitActive("Select Destination Directory")

ControlSetText("Select Destination Directory", "", "Edit1", "D:\Program Files\FlashGet" )

ControlClick ( "Select Destination Directory", "OK", "Button1")

WinWaitActive("Choose Destination Location")

ControlClick ( "Choose Destination Location", "&Next >", "Button1")

WinWaitActive("Select Program Manager Group")

ControlClick ( "Select Program Manager Group", "&Next >", "Button1")

WinWaitActive("Start Installation")

ControlClick ( "Start Installation", "&Next >", "Button1")

WinWaitActive("FlashGet")

Send("{DOWN}}{SPACE}{DOWN}{SPACE}")

;neither response when I use the following code

;ControlCommend ("FlashGet", "*********", "button1", "UnCheck")

ControlClick ( "FlashGet", "&Next >", "Button4")

WinWaitActive("Installation Complete")

ControlClick ( "Installation Complete", "&Finish >", "Button1")

when I use autoit v2, it runs perfect.

[MHz]

You may want to use ControlCommand instead of ControlCommend and it has 5 required parameters instead of 4.

You may wish to have a look at Scite4AutoIt3 on the download page, if you do not use a good editor. It has SyntaxCheck for picking these faults easy.

[zyzyeast]

You may want to use ControlCommand instead of ControlCommend and it has 5 required parameters instead of 4.

You may wish to have a look at Scite4AutoIt3 on the download page, if you do not use a good editor. It has SyntaxCheck for picking these faults easy.

Thank you very much!

I've amended the codes:

ControlCommand ("FlashGet", "xxxxxxxxxxx", "Button3", "UnCheck", "")

Is it right?

The problem is still.

[zyzyeast]

and for the command of "Send"

it always leads some problems without rhyme or reason.

when i change it to ControlClick, the problem disappear.

[MHz]

Here is a working solution to current version of FlashGet v1.71.

Run("fg171.exe")

WinWait ("Welcome")
ControlClick ( "Welcome", "&Next >", "Button1")

WinWait ("Software license")
ControlClick ( "Software license", "I &Agree", "Button1")

WinWait ("Choose Destination Location")
ControlClick ( "Choose Destination Location", "B&rowse...", "Button5")

WinWait ("Select Destination Directory")
ControlSetText ("Select Destination Directory", "", "Edit1", "D:\Program Files\FlashGet" )
ControlClick ( "Select Destination Directory", "OK", "Button1")
WinWaitClose ("Select Destination Directory")

WinWait ("Choose Destination Location")
ControlClick ( "Choose Destination Location", "&Next >", "Button1")

WinWait ("Select Program Manager Group")
ControlClick ( "Select Program Manager Group", "&Next >", "Button1")

WinWait ("Start Installation")
ControlClick ( "Start Installation", "&Next >", "Button1")

; Had to add needed text parameter to prevent the progress window passing the title.
WinWait ("FlashGet", "FlashGet shareurl service")
; You had Button3 and unknown text for ControlCommand.
ControlCommand ("FlashGet", "FlashGet shareurl service", "Button1", "UnCheck", "")
ControlClick ( "FlashGet", "&Next >", "Button2")

WinWait ("Installation Complete")
ControlClick ( "Installation Complete", "&Finish >", "Button1")

Post back if problems continue.

[zyzyeast]

OK! Thank you very much! The problem has been resolved!

But actually what do you mean of "to prevent the progress window passing the title"?

[MHz]

Between the window "Start Installation" and the window "FlashGet", I saw breifly a window in between them. I did not see the window title, but if it started with "FlashGet", then it would meet the critera of your next WinWait. Adding text to to following WinWait solved the issue. Leaving the text parameters empty exposes issues as your script had experienced.

[zyzyeast]

Could the text parameters be any words of the window or the first line?

[MHz]

Example of Au3Info display

>>>>>>>>>>> Visible Window Text <<<<<<<<<<<
Do you wish to install
This program is designed for ease
This licence is free for you

Ok, 3 lines show. You can use any of the 3 lines. I would select the line that best describes what the window means.

Example

WinWait('FlashGet', 'Do you wish to install')

"Do you wish to install" maybe the most suitable from the 3 to choose from. It is rather simple once you get used to it.

[zyzyeast]

ha, thank you for your detailed explanation!

I've got it!

And I found that when I run the same codes, it usually got a different result. I think maybe it's caused by the windows response time.

Let me learn it carefully...

[Confuzzled]

ha, thank you for your detailed explanation!

I've got it!

And I found that when I run the same codes, it usually got a different result. I think maybe it's caused by the windows response time.

Let me learn it carefully...

Put a slight pause, say Sleep(100) to give you a 0.1 second delay after each Control/Command/Click/Send - not noticeable for you, but it should be enough for Windows to catch up.