Disable Tab Focus on button with $BS_BITMAP cause hide bitmap

[Efo74]

Hello Autoit forum,

Is possible to disable Tab focus to a button with $BS_BITMAP.

My code is:

$btn  = GUICtrlCreateButton("",10,10,20,25,$BS_BITMAP)
GUICtrlSetImage($btn,"play.bmp",1)
GUICtrlSetStyle($btn,0)

If I use : GUICtrlSetStyle($btn,0) it will cause hide bitmap button.

Is there a solution to this problem ?

[Melba23]

Efo74,

At the moment you are removing all the styles from the button - you need to remove only the forced $WS_TABSTOP style like this:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#include <ButtonConstants.au3>
#include <Constants.au3>
#include <WinAPI.au3>

$hGUI = GUICreate("Test", 500, 500)

$cButton_1 = GUICtrlCreateButton("Normal", 10, 10, 80, 30)

$cButton_Pic = GUICtrlCreateButton("Bitmap", 10, 60, 80, 30, $BS_BITMAP)
GUICtrlSetImage($cButton_Pic, "Bitmap_Path")
; Get current style - includes forced $WS_TABSTOP
$iStyle   = _WinAPI_GetWindowLong(GUICtrlGetHandle($cButton_Pic), $GWL_STYLE)
; Remove $WS_TABSTOP style
GUICtrlSetStyle($cButton_Pic, BitXOR($iStyle, $WS_TABSTOP))

$cButton_2 = GUICtrlCreateButton("Normal", 10, 110, 80, 30)

GUISetState()

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch
WEnd

Look at the Setting Styles tutorial in the Wiki to get more information about styles.

M23

[Efo74]

_{Thank you very much}   

 _{It works great.}

[Melba23]

Efo74,

Glad I could help.

M23