List of installed fonts

[MyEarth]

I see less font than before but unfortunately it show always "hidden" fonts, Malgum, JHengHei, YaHei...

[BrewManNH]

HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Font Management\Inactive Fonts

That's where you will find the "hidden" fonts' names.Filter your list using that list and you should be good to go with EnumFontFamilies

[MyEarth]

That key is not present on default on Windows, here is a solution:

expandcollapse popup

#include <Array.au3>

Local $sRegFonts = "HKEY_CURRENT_USER\Software\Microsoft\Windows NT\CurrentVersion\Font Management"
Local $sFontPath = _WinAPI_ShellGetSpecialFolderPath(0x0014) ; $CSIDL_FONTS
Local $sFolderName = StringRegExpReplace($sFontPath, "^(?i)(?![A-Z]:\\$).*\\", "")
Local $aInactiveFonts, $sInactiveFonts = RegRead($sRegFonts, "Inactive Fonts")

If @OSBuild >= 7600 And $sInactiveFonts = "" Then ; key not found need to create it

    RegWrite($sRegFonts) ; create the basic key "Font Management"
    ShellExecuteWait($sFontPath, "", @WindowsDir, "open", @SW_HIDE) ; execute the Font folder
    WinWait($sFolderName, "", 1000)
    WinClose($sFolderName) ; close the folder
    Do
        Sleep(10)
         $sInactiveFonts = RegRead($sRegFonts, "Inactive Fonts")
    Until $sInactiveFonts <> "" ; wait for the registry key is created

    $aInactiveFonts =  _InactiveFonts($sInactiveFonts)
    _ArrayDisplay($aInactiveFonts, "INACTIVE_FONTS") ; test
ElseIf @OSBuild >= 7600 And $sInactiveFonts <> "" Then

    $aInactiveFonts =  _InactiveFonts($sInactiveFonts)
    _ArrayDisplay($aInactiveFonts, "INACTIVE_FONTS") ; test
EndIf



Func _InactiveFonts($sKey)
    Local $aKey = StringSplit($sKey, @LF)
    Return $aKey

EndFunc



Func _WinAPI_ShellGetSpecialFolderPath($iCSIDL, $bCreate = False)
    Local $aRet = DllCall('shell32.dll', 'bool', 'SHGetSpecialFolderPathW', 'hwnd', 0, 'wstr', '', 'int', $iCSIDL, 'bool', $bCreate)
    If @error Or Not $aRet[0] Then Return SetError(@error + 10, @extended, '')
    Return $aRet[2]
EndFunc   ;==>_WinAPI_ShellGetSpecialFolderPath

But now, how to compare the two result and have finally one list?

Edited May 28, 2015 by MyEarth

[BrewManNH]

That key should be there after you open a program that allows you access to the font list such as Word or Notepad. Windows determines which fonts the user will most likely use, and hides the rest then puts the hidden names in that key. It's determined by the language settings on your computer and the language the fonts are for. It's a Windows 7+ feature.

[iamtheky]

I think this picks off some shown ones as well, but I think all hidden ones are gone

#include <APIGdiConstants.au3>
#include <Array.au3>
#include <FontConstants.au3>
#include <WinAPIGdi.au3>

Local $aData = _WinAPI_EnumFontFamilies(0, '', $OEM_CHARSET, $TRUETYPE_FONTTYPE , '@*' , 1)

_ArrayDelete($aData , 0)

$aInactive = stringsplit(regread("HKCU\Software\Microsoft\Windows NT\CurrentVersion\Font Management" , "Inactive Fonts") , " " , 2)

For $i = ubound($aInactive) - 1 to 0 step -1
    For $k = ubound($aData) - 1 to 0 step -1
        If stringinstr($aInactive[$i] , $aData[$k][0]) AND $aData[$k][0] <> "Arial" Then
            _ArrayDelete($aData , $k)
        EndIf

    Next
Next

_ArrayDisplay($aData , "with deletes" , "|1")

 

Edited May 28, 2015 by boththose