Write data to array

[topten]

for $i = 1 to 10
next

How can I add all the appearing numbers (strings, data) to array? So that later I could say

$i[0] = 1

$i[1] = 2

etc

Note: Here I am showing may be very abstract example. In fact I will have a list of strings which will be appearing from the loop- so how can I get them into array?

[Melba23]

topten,

Do you mean something like this?

#include <Array.au3>

Global $aArray[10]

For $i = 1 To 10
    $aArray[$i - 1] = $i

Next

_ArrayDisplay($aArray, "Loaded", Default, 8)

M23

[topten]

I myself not sure about it

I will try to explain

For example you are getting some list of words from the loop (regexp)

$infoarray = StringRegExp($info, '(.*?);', 3)

for $i = 0 to Ubound ($infoarray)-1

;  here  $infoarray[i$] is my resulted string

And here I need this string to be written  into some $y, so later when I get $y[0] - I have first string written into $y, and $y[1] - second string written into $y etc

next

 

Something like that ...

Edited August 12, 2015 by topten

[Melba23]

topten,

That makes no sense at all. You have an array of results in $infoarray - why do you need to get these values into another array before accessing them? If you will be overwriting the initial array then just copy it into another like this:

#include <Array.au3>

$aInfoArray = StringSplit("0123456789", "")

_ArrayDisplay($aInfoArray, "Initial return", Default, 8)

$aCopyArray = $aInfoArray ; Copy the array

_ArrayDisplay($aCopyArray, "Copy", Default, 8)

If that is not the answer then I suggest you try and write some pseudo-code (plain language logic flow) so that we can better understand what it is you want to do - because if you have trouble formulating it how are we supposed to understand?

M23

[topten]

I try to paraphrase, may be I have missed something

$data = fileread ("words.txt")

$g = StringRegExp($data, '(.*?);', 3) ; the words are separated by ";"

for $i = 0 to Ubound($g)-1

$g[$i] - here is  every word I am getting from the list

$word = $g[$i]

getspecialdatafromtheword ($word) ; here I am getting special data which is accordingly to this word (my custom function)


;;;;;;;;;;

And here I need   $specialdata write into some $y so that later I could get from $y[0] first $specialdata from $y[1] get second special data from $y[2] get third special data etc

;;;;;;;;;;

next

func     getspecialdatafromtheword ($word)

;;;;;; my function

Return $specialdata

endfunc

I hope this is more clear. Is such possible?

 

[Melba23]

topten,

Perhaps this:

expandcollapse popup

#include <Array.au3>
#include <StringConstants.au3>
#include <MsgBoxConstants.au3>

; Simulate reading file
$sData = "0123456789"

; Simulate RegEx split into "words"
$g = StringSplit($sData, "", $STR_NOCOUNT)

; The "data" array
_ArrayDisplay($g, "Words", Default, 8)

; Create array to hold "special data" - same size as the data array
Global $y[UBound($g)]


; Now loop though the data
For $i = 0 To UBound($g) - 1

    ; Extract "word"
    $word = $g[$i]
    ; Save "special data" into new array
    $y[$i] = _getspecialdatafromtheword($word)

Next

; The "special data" array
_ArrayDisplay($y, "Special data", Default, 8)

; And to show that they 2 arrays are linked
For $i =  0 To UBound($g) - 1
    MsgBox($MB_SYSTEMMODAL, $i, $g[$i] & @CRLF & $y[$i])
Next

Func _getspecialdatafromtheword($sWord)
    ; Get the "special data"
    Return "Special data for " & $sWord
EndFunc

Any closer?

M23

[jchd]

What Melba examplified, or use _ArrayColInsert($g, 1) and store in $g[$i][1] data from word read in $g[$i][0]. That would be simpler IMVHO.

[topten]

Great thanx Melba23, that works like a charm

Great thanx jchd for your solution

[Melba23]

topten,

Glad I could help.

M23