Read Input and Save [with some options]

[terraya]

Hello everyone,

 

i am working atm at a small programm,

i want to make it work like this:

I click on "NEW" i can add a new Customer,

i want to read the input and save it (the thing is i want to make it

work for me and my friend in the internet so i think we need a internet database but firstly

i want to make it work on my laptop only for me)

 

i dont know in what to save it cuz "txt" is a bit weird , why?

becouse later i want to make a button which search for the "customer"

 

if i press on the other button not "NEW", if i press on "Search", then i have to

write the customers name in, and the info i got from the customer has to show  up

and be changeable.

 

i hope someone understand my poor english xD ,

well here is the script which is not finisht cuz i dont know how to finish the idea.

 

 

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$GUI = GUICreate("Form1", 429, 148, 249, 151)
$NEW = GUICtrlCreateButton("NEW", 48, 24, 75, 25)
$Search = GUICtrlCreateButton("Search", 48, 54, 75, 25)
$SAVE = GUICtrlCreateButton("SAVE", 328, 112, 75, 25)
$EDIT = GUICtrlCreateButton("EDIT", 328, 112, 75, 25)
GUISetState(@SW_SHOW, $GUI)
GUICtrlSetState ($SAVE, $GUI_HIDE)
GUICtrlSetState ($EDIT, $GUI_HIDE)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
         Case $NEW
            GUICtrlSetState ($SAVE, $GUI_SHOW)
            _NewCustomer()
         Case $Search
            GUICtrlSetState ($EDIT, $GUI_SHOW)
            _SearchCustomer()
         Case $SAVE
            ;not completed yet cuz i dont know in which format to save it to
            ;read it again in the GUI to make it edit able.


    EndSwitch
WEnd

Func _SearchCustomer()

   $Input2 = GUICtrlCreateInput("", 136, 57, 121, 21)

EndFunc

Func _NewCustomer()

   $Input1 = GUICtrlCreateInput("", 136, 27, 121, 21)

EndFunc

 

test functions.au3

[GordonFreeman]

You are no reason to create a control every time like in _SearchCustomer and _NewCustomer funcs. I writte an very noob example saving the data in Ini files in your computer.

When you save you need first read the value in input control, you can do it using GuiCtrlRead($Input1). $Input1 are nothing more than a variable that stores the control ID to use in functions like GuiCtrlRead, GuiCtrlSetState, GuiCtrlSetColor, etc

 

expandcollapse popup

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <GUIListBox.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
$Form1 = GUICreate("Form1", 405, 438, 192, 124)
$Label1 = GUICtrlCreateLabel("Name:", 8, 8, 35, 17)
$InputName = GUICtrlCreateInput("", 72, 8, 185, 21)
$Label = GUICtrlCreateLabel("Credit Card:", 8, 40, 59, 17)
$InputCreditCard = GUICtrlCreateInput("", 71, 34, 185, 21)
$Label3 = GUICtrlCreateLabel("Age:", 40, 72, 26, 17)
$InputAge = GUICtrlCreateInput("", 72, 72, 185, 21)
$ButtonSave = GUICtrlCreateButton("Save", 88, 112, 169, 33)
$List1 = GUICtrlCreateList("", 8, 192, 153, 227)
$Label4 = GUICtrlCreateLabel("Name:", 168, 200, 35, 17)
$LabelName = GUICtrlCreateLabel("", 208, 200, 188, 20)
$Label6 = GUICtrlCreateLabel("Credit Card:", 168, 232, 59, 17)
$LabelCreditCard = GUICtrlCreateLabel("", 232, 232, 164, 20)
$Label8 = GUICtrlCreateLabel("Age:", 168, 264, 59, 17)
$LabelAge = GUICtrlCreateLabel("", 232, 264, 164, 20)
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

$aSecNames = IniReadSectionNames("Customer.ini")

For $i = 2 to UBound($aSecNames)

    GUICtrlSetData($List1,$aSecNames[$i-1])

Next

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $ButtonSave
            $Name = GUICtrlRead($InputName)
            $CreditCard = GUICtrlRead($InputCreditCard)
            $Age = GUICtrlRead($InputAge)

            IniWrite("Customer.ini",$Name,"CreditCard",$CreditCard)
            IniWrite("Customer.ini",$Name,"Age",$Age)

            $aSecNames = IniReadSectionNames("Customer.ini")

            For $i = 2 to UBound($aSecNames)

                GUICtrlSetData($List1,$aSecNames[$i-1])

            Next
        Case $List1
            $Name = GUICtrlRead($List1)
            $CreditCard = IniRead("Customer.ini",$Name,"CreditCard","None")
            $Age = IniRead("Customer.ini",$Name,"Age","None")

            GUICtrlSetData($LabelName,$Name)
            GUICtrlSetData($LabelCreditCard,$CreditCard)
            GUICtrlSetData($LabelAge,$Age)

    EndSwitch
WEnd

 

Edited October 16, 2015 by GordonFreeman