Read INI Create Combo Read Output **Solved**

[Elephant007]

I'm attempting to me a quick GUI that will read an ini file and make a drop down combo box displaying the printer name, select a printer name, click the button and display the printer path

The problem is when I click the button, I all the printer paths or just the last printer path

 

Printers.INI file sample

[PRINTERS]
Printer 1 = \\PRINTSERVER\PRINTER1
Printer 2 = \\PRINTSERVER\PRINTER2
Printer 3 = \\PRINT01\BW_PRINTER_1

Thank you in advance for your help

EDIT

Here's my script in it's ugly glory... I'm just tying to get it going first

#include <GUIConstantsEx.au3>

Local $APRINTERS = IniReadSection("Printers.ini", "PRINTERS")
Local $SPRINTERS = ""
For $I = 1 To $APRINTERS[0][0]
    $SPRINTERS &= "|" & $APRINTERS[$I][0]
Next
GUICreate("My GUI combo")
$Button = GUICtrlCreateButton('PrinterPath', 10, 40, 100, 100)
If @error Then MsgBox(4096, "", "Error occurred, probably no INI file.")
$combo = GUICtrlCreateCombo("", 10, 10, 100, 40)
GUICtrlSetData(-1, $SPRINTERS)


GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button
            For $I = 1 To $APRINTERS[$I][1]
            Next
            MsgBox(0, '', $APRINTERS[$I][1])
    EndSwitch
WEnd

 

Edited November 4, 2015 by Elephant007

[BrewManNH]

Where's your script?

[Elephant007]

Where's your script?

Edit my op to show the script

[BrewManNH]

Here's one way to do it.

#include <GUIConstantsEx.au3>
Global $sIniFile = "Printers.ini"
Global  $APRINTERS = IniReadSection($sIniFile, "PRINTERS")
If @error Then MsgBox(4096, "", "Error occurred, probably no INI file.") ; Moved this line to where it should have been
Global $SPRINTERS = ""
For $I = 1 To $APRINTERS[0][0]
    $SPRINTERS &= "|" & $APRINTERS[$I][0]
Next
GUICreate("My GUI combo")
$Button = GUICtrlCreateButton('PrinterPath', 10, 40, 100, 100)
$combo = GUICtrlCreateCombo("", 10, 10, 100, 40)
GUICtrlSetData(-1, $SPRINTERS)


GUISetState()

While 1
    $msg = GUIGetMsg()
    Switch $msg
        Case $GUI_EVENT_CLOSE
            ExitLoop
        Case $Button
            MsgBox(0, '', IniRead($sIniFile, "Printers", GUICtrlRead($combo), "Error"))
    EndSwitch
WEnd

Ask if you have any questions.

[Elephant007]

That worked perfect, thank you

The only question I have is, how does clicking the button know how to read and display the printer path?

[BrewManNH]

The GUICtrlRead reads the contents of the combobox, the IniRead takes that text and uses it as the key to read from in the INI file.