Jump to content

Recommended Posts

Posted

Hello ! 

I want to add scroll-bar to my Tab item. I was searching on google...but I didnt find anything usable. I tried to do it but I didnt successed. Can you help me ? 

I found that i have to use there a child gui but it didnt work too. Thank you !

My code :

#include <GUIConstantsEx.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>
#Region ### START Koda GUI section ### Form=
Global $Form1 = GUICreate("MainGUI", 349, 277, 208, 215)
Global $Tab1 = GUICtrlCreateTab(24, 32, 289, 193)
Global $TabSheet1 = GUICtrlCreateTabItem("GUI1")
Global $TabSheet2 = GUICtrlCreateTabItem("GUI2")
Global $TabSheet3 = GUICtrlCreateTabItem("GUI3")
GUICtrlCreateTabItem("")
GUISetState(@SW_SHOW)
#EndRegion ### END Koda GUI section ###

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

PS: I want scrollbar only in GUI1 no on the others.

  • Moderators
Posted

ssamko,

You need to manage the hiding/showing of the child GUI yourself:

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

#include "GUIScrollbars_Ex.au3"

$hGUI = GUICreate("Test", 500, 500)

$cTab = GUICtrlCreateTab(10, 10, 480, 480)

$c_Tab_0 = GUICtrlCreateTabItem("Tab 0")
$c_Tab_1 = GUICtrlCreateTabItem("Tab 1")
$c_Tab_2 = GUICtrlCreateTabItem("Tab 2")
GUICtrlCreateTabItem("")

GUISetState()

; Create child GUI to hold scrollable zone on Tab 1
$hChild = GUICreate("", 400, 400, 30, 50, $WS_POPUP, $WS_EX_MDICHILD, $hGUI)
GUISetState(@SW_HIDE)

; Add scrollbars
_GUIScrollbars_Generate($hChild, 800, 800)

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cTab

            ; Check which tab was selected
            Switch GUICtrlRead($cTab)
                Case 1
                    ; Show child if Tab 1
                    GUISetState(@SW_SHOW, $hChild)
                Case Else
                    ; Hild child if not
                    GUISetState(@SW_HIDE, $hChild)
            EndSwitch

    EndSwitch
WEnd

Note how easy it is to create scrollbars using my Scrollbars UDF - the link is in my sig.

M23

Public_Domain.png.2d871819fcb9957cf44f4514551a2935.png Any of my own code posted anywhere on the forum is available for use by others without any restriction of any kind

Open spoiler to see my UDFs:

  Reveal hidden contents

 

Create an account or sign in to comment

You need to be a member in order to leave a comment

Create an account

Sign up for a new account in our community. It's easy!

Register a new account

Sign in

Already have an account? Sign in here.

Sign In Now
  • Recently Browsing   0 members

    • No registered users viewing this page.
×
×
  • Create New...