Usage of For Statement within a For Statement

[TheCrimsonCrusader]

I'm working on this script that reads a server name line by line from a file named "serverlist.txt".  Then after it reads the respective server name, it then does a RegEnumKey to list all of the sub-registry keys under HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages.

The problem is it will read the first server name and gather all of the sub-registry keys for it and write it to $servername\Hotfixes.log ($servername is a directory that will already exist), but it won't do that for the remaining servers listed in the serverlist.txt.  So my problem is with how the second "for" statement works in conjunction with the first "for" statement and I don't know how to fix it.

Any ideas?

The servers listed in the serverlist.txt are on their own line as follows:

server1

server2

server3

etc.

 

#include <File.au3>
#include <MsgBoxConstants.au3>


$serverlist = "serverlist.txt"
FileOpen($serverlist, 0)


For $i = 1 to _FileCountLines($serverlist)
    $servername = FileReadLine($serverlist, $i)
Local $sSubKey = ""
For $i = 1 To 1000
    $sSubKey = RegEnumKey("HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages", $i)
    If @error Then ExitLoop
    FileWriteLine($servername & "\Hotfixes.log",$sSubKey)
Next
Next
FileClose($serverlist)

 

 

Edited March 9, 2016 by TheCrimsonCrusader

[Melba23]

TheCrimsonCrusader,

if you have nested For loops, you must use a different loop variable for each one. At present you are increasing the outer loop counter when running the inside loop and so when you first hit the outer Next it falls through. Try this:

#include <File.au3>
#include <MsgBoxConstants.au3>

$serverlist = "serverlist.txt"
FileOpen($serverlist, 0)

For $i = 1 To _FileCountLines($serverlist)
    $servername = FileReadLine($serverlist, $i)
    Local $sSubKey = ""
    For $j = 1 To 1000
        $sSubKey = RegEnumKey("HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages", $j)
        If @error Then ExitLoop
        FileWriteLine($servername & "\Hotfixes.log", $sSubKey)
    Next
Next
FileClose($serverlist)

But you could avoid having 2 loops by doing this:

#include <File.au3>
#include <MsgBoxConstants.au3>

$serverlist = "serverlist.txt"
FileOpen($serverlist, 0)

While 1
    $servername = FileReadLine($serverlist)
    If @error Then ExitLoop
    Local $sSubKey = ""
    For $i = 1 To 1000
        $sSubKey = RegEnumKey("HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages", $i)
        If @error Then ExitLoop
        FileWriteLine($servername & "\Hotfixes.log", $sSubKey)
    Next
WEnd
FileClose($serverlist)

as AutoIt is intelligent enough to read the lines in order and break out of the loop when it has read the last one. For large files this is seriously quicker than using a count with FileReadLine as explained in the Help file.

M23

[AutID]

38 minutes ago, Melba23 said:

 

But you could avoid having 2 loops by doing this:

#include <File.au3>
#include <MsgBoxConstants.au3>

$serverlist = "serverlist.txt"
FileOpen($serverlist, 0)

While 1
    $servername = FileReadLine($serverlist)
    If @error Then ExitLoop
    Local $sSubKey = ""
    For $i = 1 To 1000
        $sSubKey = RegEnumKey("HKLM64\SOFTWARE\Microsoft\Windows\CurrentVersion\Component Based Servicing\Packages", $i)
        If @error Then ExitLoop
        FileWriteLine($servername & "\Hotfixes.log", $sSubKey)
    Next
WEnd
FileClose($serverlist)

as AutoIt is intelligent enough to read the lines in order and break out of the loop when it has read the last one. For large files this is seriously quicker than using a count with FileReadLine as explained in the Help file.

M23

Isn't that two loops as well?!