Updating label text

[Marzupilami]

Okay, so this is my problem: When I have my code like this, the text updates as I want it to do, but I am unable to use the close/minimize control buttons.

$var1 = 0

GUICreate("", 200, 200)
$Label1 = GUICtrlCreateLabel($var1, 100, 100, 50, 50)
GUICtrlSetFont(-1, 38, 400, 0, "Arial Rounded MT Bold")
GUICtrlSetColor(-1, 0xFFFFFF)
GUISetState(@SW_SHOW)

Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
Sleep(1000)
Exit

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case -3
            Exit

    EndSwitch
WEnd

If I have the other way around, like this, I can close and minimize, but it doesn't update the label text.

$var1 = 0

GUICreate("", 200, 200)
$Label1 = GUICtrlCreateLabel($var1, 100, 100, 50, 50)
GUICtrlSetFont(-1, 38, 400, 0, "Arial Rounded MT Bold")
GUICtrlSetColor(-1, 0xFFFFFF)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case -3
            Exit

    EndSwitch
WEnd

Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
Sleep(1000)
Exit

Help would be appreciated.

[funkey]

You can use AdlibRegister to do this

 

GUICreate("", 200, 200)
Global $Label1 = GUICtrlCreateLabel("1", 100, 100, 50, 50)
GUICtrlSetFont(-1, 38, 400, 0, "Arial Rounded MT Bold")
GUICtrlSetColor(-1, 0xFFFFFF)
GUISetState(@SW_SHOW)

AdlibRegister("_Count", 1000)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case -3
            Exit
    EndSwitch
WEnd


Func _Count()
    Local Static $var1 = 1
    $var1 += 1
    If $var1 = 4 Then Exit
    GUICtrlSetData($Label1, $var1)
EndFunc

 

[Melba23]

Marzupilami,

Just look for the events during the pauses:

#include <GUIConstantsEx.au3>

$var1 = 0

GUICreate("", 200, 200)
$Label1 = GUICtrlCreateLabel($var1, 100, 100, 50, 50)
GUICtrlSetFont(-1, 38, 400, 0, "Arial Rounded MT Bold")
GUICtrlSetColor(-1, 0xFFFFFF)
GUISetState(@SW_SHOW)

_Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
_Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
_Sleep(1000)
$var1 += 1
GUICtrlSetData($Label1, $var1)
_Sleep(1000)
Exit

Func _Sleep($iDelay)
    $nBegin = TimerInit()
    While TimerDiff($nBegin) < $iDelay
        Switch GUIGetMsg()
            Case $GUI_EVENT_CLOSE
                Exit
        EndSwitch
    WEnd
EndFunc

M23

[Marzupilami]

@funkey, @Melba23: Thank you for your quick responses! I'm sorry I was a bit unclear. In fact I don't want a counter like the one I showed. What I want is that as thevalue of $var1 changes during the script (my real script is much longer) I want the label text to update with it. Could you help me with that?

[Melba23]

Marzupilami,

It always helps to give as much detail as possible when asking a question - then responders do not waste their time producing code which does not do what is actually required.

Two possible solutions to your problem spring to mind:

1. When you reach the part of your script where you change the value of the variable in question, update the label at that point.
2. Use Adlib to read the current value and update the label, much as funkey has already suggested.

If you want more focused help, I suggest posting your script so we can see just what might best fit the bill.

M23

[funkey]

Use the OnEvent-Mode.This makes it easier to handle larger scripts and avoids such problems.

Edited July 13, 2016 by funkey

[Melba23]

funkey,

I must disagree with that last remark - I have used both OnEvent and MessageLoop modes in large scripts and I would argue that the latter is easier to code and just as efficient.

M23