GUI CREATION

[CODEXTRM]

anyone have time to  write a little script for me ??  just need  4 input slots and a save button that will save to my folder on desktop , for example :

I want to enter info like  (name, phone#, model, part)  then be able to click save  so that it creates a txt file inside a selected folder . its notes I take at work  this way I can refrence back to them later

thanks so much in advance

 

Edited August 23, 2016 by CODEXTRM

[Melba23]

CODEXTRM,

Just this once:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <FileConstants.au3>
#include <MsgBoxConstants.au3>

$sPath = @ScriptDir & "\List.txt" ; Place "Your_Required_File_Path" here

$hGUI = GUICreate("Test", 500, 500)

GUICtrlCreateLabel("Name:", 10, 10, 200, 20)
GUICtrlCreateLabel("Phone:", 10, 70, 200, 20)
GUICtrlCreateLabel("Model:", 10, 130, 200, 20)
GUICtrlCreateLabel("Part:", 10, 190, 200, 20)

$cName = GUICtrlCreateInput("", 10, 30, 200, 20)
$cPhone = GUICtrlCreateInput("", 10, 90, 200, 20)
$cModel = GUICtrlCreateInput("", 10, 150, 200, 20)
$cPart = GUICtrlCreateInput("", 10, 210, 200, 20)

$cSave = GUICtrlCreateButton("Save", 10, 300, 80, 30)

$cRead = GUICtrlCreateButton("Read", 10, 350, 80, 30)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cSave
            $sData = GUICtrlRead($cName) & @CRLF & GUICtrlRead($cPhone) & @CRLF & GUICtrlRead($cModel) & @CRLF & GUICtrlRead($cPart) & @CRLF & "~~~~" & @CRLF
            $hFile = FileOpen($sPath, $FO_APPEND)
            FileWrite($hFile, $sData)
            FileClose($hFile)
            For $i = $cName To $cPart
                GUICtrlSetData($i, "")
            Next
        Case $cRead
            $sData = FileRead($sPath)
            MsgBox($MB_SYSTEMMODAL, "Content", $sData)
    EndSwitch

WEnd

M23

[CODEXTRM]

Thank you very much now I have something to study so I can learn how to do it myself

 

[Melba23]

CODEXTRM,

Please ask if you have any questions - but do try and find an answer in the Help file first.

M23