How to get double click in label?

[Melque_Lima]

hi, 

i'm trying to get the double click in a specific label, i try it bellow:

 

$label = GUICtrlCreateLabel("0", 259, 410,220, 40)

Func WM_NOTIFY($hWnd, $iMsg, $iwParam, $ilParam)

    Local $tNMHDR = DllStructCreate($tagNMHDR, $ilParam)
    If HWnd(DllStructGetData($tNMHDR, "hWndFrom")) = $label And DllStructGetData($tNMHDR, "Code") = $NM_DBLCLK Then
          msgbox(0,"","clicked 2 times")
    EndIf

    Return $GUI_RUNDEFMSG

EndFunc

but no sucess!!!

 

[Melba23]

Melque_Lima,

There is a very useful search function at top-right of the page. A quick search found several solutions.

  Reveal hidden contents

expandcollapse popup

#include <GUIConstants.au3>
#include <WindowsConstants.au3>
#include <WinApi.au3>

#include <StaticConstants.au3>

Global $STN_DBLCLK = 1

$hGUI = GUICreate("Double Click", 500, 500)

$cLabel = GUICtrlCreateLabel("Double click this!", 10, 10, 200, 20)
GUICtrlSetBkColor($cLabel, 0xFFCCCC)

GUISetState()

GUIRegisterMsg($WM_COMMAND, "_WM_COMMAND")

While 1
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $cLabel
            ConsoleWrite("Label clicked" & @CRLF)
    EndSwitch
WEnd

Func _WM_COMMAND($hWndFrom, $iMsg, $wParam, $lParam)
    Local $iIDFrom = BitAND($wParam, 0xFFFF) ; Low Word
    Local $iCode = BitShift($wParam, 16) ; Hi Word

    Switch $hWndFrom
        Case $hGUI
            Switch $iIDFrom
                Case $cLabel
                    If $iCode = $STN_DBLCLK  Then
                        ConsoleWrite("Label doubleclicked!" & @CRLF)
                    EndIf
            EndSwitch
    EndSwitch
EndFunc   ;==>_WM_COMMAND

 

M23