Convert Dec to Binary - but Ones and Zeros

[WoodGrain]

Hi All,

Trying to convert a number to binary zeros and ones but I'm getting a result I don't understand and looks more like hex than binary.

Here's my basic code:

$myNum = 11
$myNumBin = Binary($myNum)
MsgBox(0, "Binary result", $myNumBin)

What I want is "1011", what I get is 0x0B000000.

Thanks!

Edited December 8, 2016 by WoodGrain
Wrong syntax

[czardas]

Try this:

MsgBox(0, "", DecToBase(11, 2))

Func DecToBase($iInt, $iBase) ; for bases 2 to 9
    Local $iRem, $sRet = ''
    While $iInt > $iBase -1
        $iRem = Mod($iInt, $iBase)
        $sRet = $iRem & $sRet
        $iInt = Int(($iInt - $iRem) /$iBase)
    WEnd
    Return $iInt & $sRet
EndFunc ;==> DecToBase

To reverse the process you can use this:

MsgBox(0, "", BaseToDec('1011', 2))

Func BaseToDec($sInt, $iBase) ; bases 2 to 9 only
    Local $iRet = 0, $iLen = StringLen($sInt)
    For $i = 1 To $iLen
        $iRet += StringMid($sInt, $i, 1) * $iBase ^ ($iLen - $i)
    Next
    Return $iRet
EndFunc ;==> BaseToDec

 

Edited December 8, 2016 by czardas

[WoodGrain]

That worked perfectly, thanks!

I note it does bases 2 - 9, would it be complex to allow up to base 16 so I can convert it to hex as well?

[czardas]

It's not so complicated, but unless you need bases 11 to 15, you might as well use Hex() and Dec(). I don't have much time this morning. You could try this old code of mine:
 http://www.czardas.co.uk/repository/math10.au3

The code I posted in this thread can also be modified to convert larger numbers (up to Int64) by replacing the operators with operator64 functions (see my signature). Currently, these conversion functions only work for doubles ~ up to 15 decimal digits.

Edited December 8, 2016 by czardas

[WoodGrain]

No worries, thanks very much.

Actually, yeah, hex() works as expected

$myNum = 30
$myNumHex = Hex($myNum, 2)
MsgBox(0, "Hex result", $myNumHex)

Returns 1E

Edited December 8, 2016 by WoodGrain
Update after testing

[BrewManNH]

18 hours ago, czardas said:

$iInt = Int(($iInt - $iRem) /$iBase)

This line could be written like this with no change in output.

$iInt = Int($iInt / $iBase)

 

[czardas]

@BrewManNH Well spotted! By all means change it.

Instead of that, if I implement Operator64 functions, Int() could be removed. It should not really be needed here neither, but because of rounding inaccuracies, I added it to be on the safe side. That's also why I decided on division by a real factor (subtracting the remainder first): I don't trust double precision to always return an accurate result.

It's a while since I wrote this and I'm trying to remember everything I was thinking at the time. I must have written it that way because of the aforementioned reasons.

Edited December 9, 2016 by czardas

[czardas]

I have modified this method to be compatible with all numbers within the positive Int64 range. This example requires operator64.au3 (see link in my signature).

CODE MOVED HERE:

Edited December 13, 2016 by czardas