GUI Menu Questions

[argv1]

Hi,

working on my first autoit GUI an got some questions.

Is it possible to get an action on the first menu level

For example:

$StartMenu = GUICtrlCreateMenu("Datei")

...

while 1
    Switch GUIGetMsg()
        Case $StartMenu
            MsgBox(0, "Test", "yes this works")

(currently this does not work for me)

Currently I have to create GUICtrlCreateMenuItem 's this will leed to a result

 

And a 2nd question. I saw many time this:

$StartMenu = GUICtrlCreateMenu("&Datei")

For what does I need the ampersand? If I leave out the & nothing seems to change

 

Thank you very much in advance

 

Edited December 30, 2016 by argv1

[Valuater]

Glad you know how to use Autoit code tags!!

 

Can you please give us the completed demo script... with errors is ok

 

8)

[Melba23]

argv1,

Please do not post support questions in the Examples section - it does quite clearly say that:

Quote

Do not post general support questions here, instead use the AutoIt Help and Support forums.

You can detect a top-level menu event like this:

#include <GUIConstantsEx.au3>
#include <MsgBoxConstants.au3>

$hGUI = GUICreate("Test", 500, 500)

$mFilemenu = GUICtrlCreateMenu("&File")
$mExititem = GUICtrlCreateMenuItem("E&xit", $mFilemenu)
$mSpecialitem = GUICtrlCreateMenuItem("&Special", -1)
$mHelpmenu = GUICtrlCreateMenu("?")
$mAboutitem = GUICtrlCreateMenuItem("&About", $mHelpmenu)

GUISetState()

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $mExititem
            Exit
        Case $mSpecialitem
            MsgBox($MB_SYSTEMMODAL, "Hi", "I can be actioned!")
        Case $mAboutitem
            MsgBox($MB_SYSTEMMODAL, "Solved", "Thank Jos for that!")
    EndSwitch

WEnd

And adding an ampersand (&) to the menu text allows you to use the next letter as a "hotkey" when you press the Alt key first - you will see that the letter is underlined.

M23

Edited December 30, 2016 by Melba23
Typo