How to Create GUI Tab on Left/Right ?

[Trong]

Like this:

GUICtrlCreateTab on Top eg:

expandcollapse popup

#include <GUIConstantsEx.au3>

Example()

Func Example()
    GUICreate("My GUI Tab") ; will create a dialog box that when displayed is centered

    GUISetBkColor(0x00E0FFFF)
    GUISetFont(9, 300)

    GUICtrlCreateTab(10, 10, 200, 100)

    GUICtrlCreateTabItem("tab0")
    GUICtrlCreateLabel("label0", 30, 80, 50, 20)
    GUICtrlCreateButton("OK0", 20, 50, 50, 20)
    GUICtrlCreateInput("default", 80, 50, 70, 20)

    GUICtrlCreateTabItem("tab----1")
    GUICtrlCreateLabel("label1", 30, 80, 50, 20)
    GUICtrlCreateCombo("", 20, 50, 60, 120)
    GUICtrlSetData(-1, "Trids|CyberSlug|Larry|Jon|Tylo|guinness", "Jon") ; default Jon
    GUICtrlCreateButton("OK1", 80, 50, 50, 20)

    GUICtrlCreateTabItem("tab2")
    GUICtrlSetState(-1, $GUI_SHOW) ; will be display first
    GUICtrlCreateLabel("label2", 30, 80, 50, 20)
    GUICtrlCreateButton("OK2", 140, 50, 50)

    GUICtrlCreateTabItem("") ; end tabitem definition

    GUICtrlCreateLabel("label3", 20, 130, 50, 20)

    GUISetState(@SW_SHOW)

    Local $idMsg
    ; Loop until the user exits.
    While 1
        $idMsg = GUIGetMsg()

        If $idMsg = $GUI_EVENT_CLOSE Then ExitLoop
    WEnd
EndFunc   ;==>Example

 

[Melba23]

You,

Using my GUIExtender UDF allows you to do something like this quite easily:

expandcollapse popup

#include <GUIConstantsEx.au3>

#include "GUIExtender.au3"

Global $aLabel[6], $aColour[] = [0, 0xFF0000, 0x00FF00, 0xAAAAFF, 0xFFFF00, 0x00FFFF]

$hGUI = GUICreate("Test", 2600, 500, 100, 100)

For $i = 1 To 5
    $aLabel[$i] = GUICtrlCreateLabel("Tab " & $i, 0, ($i * 100) - 100, 100, 100)
    GUICtrlSetBkColor(-1, $aColour[$i])
    GUICtrlSetResizing(-1, $GUI_DOCKSIZE)
Next

_GUIExtender_Init($hGUI, 1)

For $i = 1 To 5

    $iSection = _GUIExtender_Section_Create($hGUI, (500 * $i) - 400, 500)
    GUICtrlCreateLabel("This is screen " & $iSection, (500 * $i) - 400, (100 * $i) - 100, 500, 100)
    GUICtrlSetBkColor(-1, $aColour[$i])
    _GUIExtender_Section_Activate($hGUI, $iSection)

Next

_GUIExtender_Section_Create($hGUI, -99)

$iCurrSection = 1
For $i = 2 To 5
    _GUIExtender_Section_Action($hGUI, $i, 0)
Next

GUISetState()


While 1

    $imsg = GUIGetMsg()
    Switch $iMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case Else
            For $i = 1 To 5
                If $iMsg = $aLabel[$i] And $i <> $iCurrSection Then
                    _GUIExtender_Section_Action($hGUI, $iCurrSection, 0)
                    _GUIExtender_Section_Action($hGUI, $i, 1)
                    $iCurrSection = $i
                    ExitLoop
                EndIf
            Next
    EndSwitch

    _GUIExtender_EventMonitor($hGUI, $iMsg)

WEnd

The UDF link is in my sig.

M23