Lose control focus on click

[Cotino]

Hi,

The title is confusing, so here's what i want :

When I click on the GUI window, outside of any control so just the window, remove focus on any control who has it.
So if i click on an input and select the text, then click outside of the input, the input loses focus and doesnt select the text anymore.

Is there a way to do that ?

#include <GUIConstants.au3>

Opt("GUIOnEventMode", 1)

Global $GUImain = GUICreate("", 150, 50)
    GUISetOnEvent($GUI_EVENT_CLOSE, "EndGUI")

Global $input = GUICtrlCreateInput("Something", 5, 5, 140, 20)

GUISetState()

While 1
    Sleep(100)
WEnd

Func EndGUI()
    Exit
EndFunc

 

Edited August 17, 2017 by Cotino

[Melba23]

Cotino,

Not too difficult:

#include <GUIConstantsEx.au3>
#include <GuiEdit.au3>

Opt("GUIOnEventMode", 1)

Global $GUImain = GUICreate("", 150, 50)
    GUISetOnEvent($GUI_EVENT_CLOSE, "EndGUI")
    GUISetOnEvent($GUI_EVENT_PRIMARYUP, "Click")

Global $input = GUICtrlCreateInput("Something", 5, 5, 140, 20)

GUISetState()

While 1
    Sleep(100)
WEnd

Func EndGUI()
    Exit
EndFunc

Func Click()
    ; Check which control in under the cursor
    $aInfo = GUIGetCursorInfo($GUImain)
    If $aInfo[4] <> $input Then
        ; If it is not the input then clear the input selection
        _GUICtrlEdit_SetSel($input, -1, -1)
    EndIf

EndFunc

M23

[Cotino]

Great answer as always Melba.

Thanks !

[Cotino]

Uhm, is there a way to not have to test if $aInfo[4] is different than every control ?

I kinda have 67 controls on my current GUI and they are not in an array.

Edited August 17, 2017 by Cotino

[Melba23]

Cotino,

Try changing the condition to this:

If $aInfo[4] = 0 Then

Now it should work whenever you are not over any of your numerous controls - if you are then they should take focus anyway.

M23

[Cotino]

Perfect.

One last thing though, if i start clicking inside the input to select text, and release click outside of the input, it removes focus on the input.

Any way to avoid that ?

[Melba23]

Cotino,

Try changing  GUISetOnEvent($GUI_EVENT_PRIMARYUP, "Click") to $GUI_EVENT_PRIMARYDOWN.

M23

[Cotino]

Exactly what i was looking for.

Thanks again.

[Melba23]

Cotino,

Glad I could help.

M23