Automatically resize font

[Belini]

Is it possible to automatically resize fonts when controls are resized?

#include <GUIConstantsEx.au3>
#include <StaticConstants.au3>
#include <WindowsConstants.au3>

$Form1 = GUICreate("Form1", 623, 449, 192, 114)
$Label1 = GUICtrlCreateLabel("TESTE 1", 176, 128, 80, 30, $SS_CENTERIMAGE + $SS_CENTER)
GUICtrlSetFont(-1, 12, 800, 0, "Arial Black")
GUICtrlSetBkColor(-1, 0XFF0000)
GUISetState(@SW_SHOW)

Sleep(1000)
GUICtrlSetData($Label1, "")
ControlMove($Form1, "", $Label1, 176, 128, 160, 60)
GUICtrlSetData($Label1, "TESTE 2")
Sleep(2000)
Exit

 

[Melba23]

Belini,

This is how I do it:

expandcollapse popup

#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>

; Set resize mode for controls
Opt("GUIResizeMode", $GUI_DOCKAUTO)

Global $iGUIInitSize = 500

$hGUI = GUICreate("Test", $iGUIInitSize, 500, -1, -1, BitOR($WS_SIZEBOX, $WS_SYSMENU))

$cButton = GUICtrlCreateButton("Resizing text", 10, 10, 80, 30)

$iLast_Control = GUICtrlCreateDummy()

GUISetState()

GUIRegisterMsg($WM_SIZE, "_WM_SIZE")

While 1

    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE
            Exit
    EndSwitch

WEnd

Func _WM_SIZE($hWnd, $iMsg, $wParam, $lParam)

    #forceref $iMsg, $wParam, $lParam

    If $hWnd = $hGUI Then
        ; Calculate required font size
        Local $aGUI_Size = WinGetClientSize($hGUI)
        $iFontSize = Int(2 * (.25 + (8 * $aGUI_Size[0] / $iGUIInitSize))) / 2
        ; Reset font size for all controls on main GUI
        For $i = 0 To $iLast_Control
            GUICtrlSetFont($i, $iFontSize)
        Next
    EndIf

EndFunc   ;==>_WM_SIZE

M23

[Belini]

@ Melba23 thanks a lot for the help, problem solved!

[Melba23]

Belini,

My pleasure as always.

M23

[Earthshine]

I wish it had been this easy in VB 6 without custom controls. I had to do all the computing based on the screen size

Edited November 24, 2017 by Earthshine

[pixelsearch]

<deleted>

Edited July 24, 2024 by pixelsearch