Turn off laptop when you close the lid or push power button (resolved)

[Belini]

I need to turn off my notebook every time the cover is closed, does anyone know how to identify when the notebook's cover has been closed?

Edited March 20, 2018 by Belini

[JLogan3o13]

Why not just use power settings to do this? Under options for closing the lid (Windows 7 and above) there is an option to shut the device down

[Belini]

I wanted to do it by code, ie to monitor the cover and turn it off when it is closed, so that I do not have to configure all the notebook's that I'm going to use the program!

[Earthshine]

then automate the setting of that power option if you can.

 

Edited March 19, 2018 by Earthshine

[Belini]

@Earthshine I tried to edit the registry following your advice but it did not work, I need it to look like this:

- Power off when you press the power button
- off when you close the cover

 

[BrewManNH]

You want to be able to do this to OTHER people's computers? Are you giving them the option to not let you do this when they run your program?

I know I'd be PISSED if your program did this to my computer without telling me.

[Earthshine]

1 hour ago, Belini said:

@Earthshine I tried to edit the registry following your advice but it did not work, I need it to look like this:

- Power off when you press the power button
- off when you close the cover

 

did you reboot? or at least log off and on again after making registry change?

[Earthshine]

oh and i found this

 

[Belini]

1 hour ago, BrewManNH said:

You want to be able to do this to OTHER people's computers? Are you giving them the option to not let you do this when they run your program?

I know I'd be PISSED if your program did this to my computer without telling me.

They are all notebooks of mine that will only be used to run my program and nothing else, will not have taskbar, explorer and nor to the task manager!

1 hour ago, Earthshine said:

oh and i found this

 

@Earthshine is now turning it off when the lid is closed, thanks for the help!

Run("powercfg.exe -SETACVALUEINDEX 381b4222-f694-41f0-9685-ff5bb260df2e 4f971e89-eebd-4455-a8de-9e59040e7347 5ca83367-6e45-459f-a27b-476b1d01c936 3", "",@SW_HIDE)
Run("powercfg.exe -SETDCVALUEINDEX 381b4222-f694-41f0-9685-ff5bb260df2e 4f971e89-eebd-4455-a8de-9e59040e7347 5ca83367-6e45-459f-a27b-476b1d01c936 3", "",@SW_HIDE)

Now to be perfect, i only need to know how to turn it off when the power button is pressed!

 

 

[Belini]

I was able to find it here: https://social.msdn.microsoft.com/Forums/en-US/06bdec1d-4ffa-4a4a-b381-9265c304cc85/command-line-configuration-of-power-button-function?forum=quebecmisc

Run("powercfg.exe -SETACVALUEINDEX 381b4222-f694-41f0-9685-ff5bb260df2e 4f971e89-eebd-4455-a8de-9e59040e7347 5ca83367-6e45-459f-a27b-476b1d01c936 3", "C:\WINDOWS\system32", @SW_HIDE)
Run("powercfg.exe -SETDCVALUEINDEX 381b4222-f694-41f0-9685-ff5bb260df2e 4f971e89-eebd-4455-a8de-9e59040e7347 5ca83367-6e45-459f-a27b-476b1d01c936 3", "C:\WINDOWS\system32", @SW_HIDE)

Run("powercfg.exe -powercfg.exe -SETACVALUEINDEX 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c 4f971e89-eebd-4455-a8de-9e59040e7347 7648efa3-dd9c-4e3e-b566-50f929386280 3", "C:\WINDOWS\system32", @SW_HIDE)
Run("powercfg.exe -powercfg.exe -SETDCVALUEINDEX 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c 4f971e89-eebd-4455-a8de-9e59040e7347 7648efa3-dd9c-4e3e-b566-50f929386280 3", "C:\WINDOWS\system32", @SW_HIDE)

 

[AdamUL]

I know you already found your answer.  I thought it would be helpful to show a function that sets multiple power options, including what you wanted.    

  

expandcollapse popup

Func _SetPowerOptions() ;Set multiple power options.

    ;Set the current power plan standby timeout ("Put the computer to sleep") to "Never".
    Local $iPowercfgReturn = RunWait("powercfg -x standby-timeout-ac 0", '', @SW_HIDE)
    If @error Or $iPowercfgReturn <> 0 Then Return SetError(1, 0, False)

    ;Set monitor timeout ("Turn off the display") to 30 minutes.
    $iPowercfgReturn = RunWait("powercfg -x monitor-timeout-ac 30", '', @SW_HIDE)
    If @error Or $iPowercfgReturn <> 0 Then Return SetError(2, 0, False)

    Local $s64Bit = ""
    If @OSArch = "X64" Then $s64Bit = "64"
    
    ;Disable Hibernate.
    Local Const $sRegKeyPower = "HKEY_LOCAL_MACHINE" & $s64Bit & "\SYSTEM\CurrentControlSet\Control\Power"
    Local $iRegWriteReturn = RegWrite($sRegKeyPower, "HibernateEnabled", "REG_DWORD", 0)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(3, @error, False)

    Local Const $sRegKeyPowerSettings = "HKEY_LOCAL_MACHINE" & $s64Bit & "\SOFTWARE\Policies\Microsoft\Power\PowerSettings"
    
    ;Disable Sleep in the Start Menu.
    Local Const $sRegKeyPowerSettingsSleepStartMenu = $sRegKeyPowerSettings & "\abfc2519-3608-4c2a-94ea-171b0ed546ab"
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsSleepStartMenu, "ACSettingIndex", "REG_DWORD", 0)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(4, @error, False)
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsSleepStartMenu, "DCSettingIndex", "REG_DWORD", 0)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(5, @error, False)

    ;Set Sleep Button to "Do Nothing"
    Local Const $sRegKeyPowerSettingsSleepButton = $sRegKeyPowerSettings & "\96996BC0-AD50-47EC-923B-6F41874DD9EB"
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsSleepButton, "ACSettingIndex", "REG_DWORD", 0)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(6, @error, False)
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsSleepButton, "DCSettingIndex", "REG_DWORD", 0)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(7, @error, False)

    ;Set Power Button to "Shut down"
    Local Const $sRegKeyPowerSettingsPowerButton = $sRegKeyPowerSettings & "\7648EFA3-DD9C-4E3E-B566-50F929386280"
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsPowerButton, "ACSettingIndex", "REG_DWORD", 3)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(8, @error, False)
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsPowerButton, "DCSettingIndex", "REG_DWORD", 3)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(9, @error, False)

    ;Set "When I close the lid" to "Shut down"
    Local Const $sRegKeyPowerSettingsCloseLid = $sRegKeyPowerSettings & "\5CA83367-6E45-459F-A27B-476B1D01C936"
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsCloseLid, "ACSettingIndex", "REG_DWORD", 3)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(10, @error, False)
    $iRegWriteReturn = RegWrite($sRegKeyPowerSettingsCloseLid, "DCSettingIndex", "REG_DWORD", 3)
    If @error Or $iRegWriteReturn <> 1 Then Return SetError(11, @error, False)

    Return True
EndFunc   ;==>_SetPowerOptions

 

Adam

[Belini]

Thanks @AdamUL will be very useful this information to change directly in the registry too!

[Earthshine]

@Belini you should change the first post of this thread's title to add the word SOLVED to it so others with this issue can see there is a solution. Thanks

[Belini]

I did not find the option to mark as resolved by this I just changed the topic title!

[Earthshine]

 That’s exactly how you do it 

[Belini]

This I had done before you spoke!

[Earthshine]

ok. sweet. thanks.

[AdamUL]

@Belini Glad I could help.  

 

Adam