Function with both HotKey and Program calls

[Melba23]

Hi all,

For reasons that are too complicated to explain in a short post I wanted to create a function which could be called by a HotKey (which ignores any parameters) and also called programmatically from within the script with various parameters. After much experimentation I came up with the following syntax and logic:

expandcollapse popup

Global $bFlag_1 = False, $bFlag_2 = False

HotKeySet("^r", "_Test")

HotKeySet("{ESC}", "_Exit")

; Default param so no action taken
_Test()

; Use param to set Flag_1 to True
_Test(1)

; And back to False
_Test(0)

; Now play with the HotKey to change Flag_2

While 1
    Sleep(10)
WEnd

Func _Test($vParam = 9999)

    #forceref $vParam ; Prevents Au3Check warning

    Eval("vParam")
    If Not @error Then
        ; Fired programatically so use parameter to set/clear Flag_1
        Switch Eval("vParam")
            Case 9999
                ; Do nothing
            Case 0
                $bFlag_1 = False
            Case 1
                $bFlag_1 = True
        EndSwitch
    Else
        ; Not fired programatically so parameter ignored and set/clear Flag_2
        $bFlag_2 = Not $bFlag_2
    EndIf

    ConsoleWrite($bFlag_1 & " - " & $bFlag_2 & @CRLF)

EndFunc

Func _Exit()
    Exit
EndFunc

Does anyone have a better way of doing this?

M23

[Jos]

No sure it is simpler but a little different approach:

Func _Test($vParam = 9999)

    #forceref $vParam ; Prevents Au3Check warning
    If Not @NumParams Then
        If Eval("vParam") <> 9999 Then
            ; Not fired programatically so parameter ignored and set/clear Flag_2
            $bFlag_2 = Not $bFlag_2
        EndIf
    Else
        ; Fired programatically so use parameter to set/clear Flag_1
        $bFlag_1 = ($vParam <> 0)
    EndIf

    ConsoleWrite($bFlag_1 & " - " & $bFlag_2 & "  @NumParams=" & @NumParams & @CRLF)

EndFunc   ;==>_Test

Jos

[Melba23]

Jos,

I like the use of @NumParams rather then using Eval twice - thanks for the tip.

M23