SprayPaint

[Oxin8]

Last night I wanted to make something fun that drew pixels onscreen and SprayPaint is the result of that. Open paint and then draw an image of any size(but make note of it) then run SprayPaint.au3. It prompts for the width, height, and file name, then it activates the paint window and reads the pixels. Then it writes an autoit script with the specified filename. The script also has an $ignorecolor (defaultly white) so it doesn't draw any pixels of that color and it looks better. If you set it to -1 it should draw everything. After it indicates that it's done, you can press ctrl+s to spray or ctrl+e to exit. The resulting autoit script draws the image at the current mouse coords every 200 milliseconds. I've included an example result so you can see. (btw, requires beta)

EDIT: ctrl+e quits the second script

For the lazy people that won't download just to see a script:

expandcollapse popup

Opt("PixelCoordMode",0)
Opt("WinTitleMatchMode",2)
Opt("ColorMode",1)

$width = InputBox("SprayPaint", "Width:")
$height = InputBox("SprayPaint", "Height:")
$fname = InputBox("SprayPaint", "File Name:")
$ignorecolor=0xFFFFFF
Dim $spray[$width][$height]
WinActivate("- Paint")
WinWaitActive("- Paint")
For $x = 65 to (64 + $width) 
    For $y = 47 to (46 + $height)
    $spray[$x-65][$y-47] = PixelGetColor($x,$y)
    Next
Next
MsgBox(0,"SprayPaint","Spray Retrieved")

$myfile = FileOpen($fname, 2)

FileWrite($myfile, 'Opt("ColorMode",1)'& @CRLF)
FileWrite($myfile, 'HotKeySet("^e","quit")'& @CRLF)
FileWrite($myfile, "While 1" & @CRLF & "$pos= MouseGetPos()" & @CRLF & "pict($pos[0],$pos[1])" & @CRLF & _
    "Sleep(200)" & @CRLF & "WEnd" & @CRLF)
FileWrite($myfile, 'Func quit()'& @CRLF & "Exit" & @CRLF & "EndFunc" & @CRLF)
FileWrite($myfile, 'Func drawpix($dc,$x,$y,$color)' & @CRLF & _
    'DllCall ("gdi32.dll", "long", "SetPixel", "long", $dc[0], "long", $x, "long", $y, "long", $color)' _
     & @CRLF & "EndFunc" & @CRLF)
FileWrite($myfile, "Func pict($x,$y)" & @CRLF & '$dc= DllCall ("user32.dll", "int", "GetDC", "hwnd", "")' & @CRLF)
For $x = 0 to ($width-1)
    For $y = 0 to ($height-1)
    If $spray[$x][$y] <> $ignorecolor Then FileWrite ( $myfile, "drawpix($dc,$x+" & $x & ",$y+" & $y & ",0x" & hex($spray[$x][$y]) & ")" & @CRLF)
    Next
Next
FileWrite($myfile,'DllCall ("user32.dll", "int", "ReleaseDC", "hwnd", 0,  "int", $dc[0])' & @CRLF & "EndFunc")
FileClose($myfile)
MsgBox(0,"SprayPaint","Spray Written To " & $fname)

waiting()

Func waiting()
HotKeySet("^s","spray")
HotKeySet("^e","quittime")
While 1
   Sleep(50)
WEnd
EndFunc

Func quittime()
   Exit
EndFunc

Func spray()
    $dc= DllCall ("user32.dll", "int", "GetDC", "hwnd", "")
    $pos= MouseGetPos ()
    For $x = 0 to ($width-1)
    For $y = 0 to ($height-1)
        If $spray[$x][$y] <> $ignorecolor Then DllCall ("gdi32.dll", "long", "SetPixel", "long", $dc[0], "long", $pos[0] + $x, "long", $pos[1] + $y, "long", "0x" & hex($spray[$x][$y]))
    Next
    Next
    DllCall ("user32.dll", "int", "ReleaseDC", "hwnd", 0,  "int", $dc[0])
EndFunc

hearts.au3

spraypaint.au3

Edited January 15, 2006 by Oxin8

[cdkid]

nice

[GrungeRocker]

wow thats fun =)

[BigDod]

A person can have some fun with this. It may be worth building in a hotkey to stop the second script.

[Oxin8]

A person can have some fun with this. It may be worth building in a hotkey to stop the second script.

done.

[cppman]

lol. pretty cool.

[jaenster]

funny

[AlmarM]

How it works ???

I think im doing anything wrong...

I've started Spraypaint filled in the inputboxes and then ??