RegExp: repeatable pattern

[Iczer]

I need to parse string with unknown beforehand count of repeats into another string using StringRegExpReplace()

from : <div class='tags'><h3>Tags</h3><ul><li>aaa</li><li>bbb</li><li>ccc</li><li>ddd</li><li>eee</li></ul></div>

to : aaa, bbb, ccc, ddd, eee

But i still cannot grasp repeatable patterns in StringRegExpReplace()... with array it simple, but with string...

$sTags = StringRegExpReplace($aEntry[$i],"(?si).+?<h3>Tags</h3><ul>((<li>\w++</li>)\K).++","$2"

 

[seadoggie01]

This mostly satisfies your request, but leaves a trailing ", ":

$sTags = StringRegExpReplace($aEntry[$i], "(?:.*?)<li>(.*?)<\/li>(?:(?!<\/?li>).)*", "$1, ")

Spoiler

Explanation: (?:.*?)<li>(.*?)<\/li>(?:(?!<\/?li>).)*

(?:.*?) - Capture everything before the first <li> tag, only expanding as needed (lazy)

<li>(.*?)<\/li> - Capture everything between <li> tags, only expanding as needed (lazy)

(?:(?!<\/li>).)* - The beast... uses a negative lookahead to ensure that we don't capture a trailing <li> tag, basically captures everything after the final </li>

Personally though, I would match everything between <li> and </li> tags with StringRegExp option 3 and concatenate the results back together...

Func ConcatRegExp($sText)
    
    Local $aResults = StringRegExp($sText, "<li>(.*?)<\/li>", 3)
    If @error Then Return SetError(1, 0, False)
    
    Local $sReturn = ""
    For $i=0 To Ubound($aResults) - 1
        $sReturn &= $aResults[$i] & ", "
    Next
    
    Return StringTrimRight($sReturn, 2)
    
EndFunc

Edited October 14, 2020 by seadoggie01
Added explanation

[Iczer]

Thanks! This leaves trailing "</li>" in resulting string, but it still good result as it faster than have to deal with array after StringRegExp()

[seadoggie01]

Do you have different data? When I try it I don't get a trailing tag:

ConsoleWrite(StringTrimRight(StringRegExpReplace("<div class='tags'><h3>Tags</h3><ul><li>aaa</li><li>bbb</li><li>ccc</li><li>ddd</li><li>eee</li></ul></div>", "(?:.*?)<li>(.*?)<\/li>(?:(?!<\/?li>).)*", "$1, "), 2) & @CRLF)