Help me please for StringRegExpReplace

[mixim]

Local $key_G = Chr(0xD0) ;uppercase Ğ
Local $key_I = Chr(0xDD) ;uppercase İ
Local $key_S = Chr(0xDE) ;uppercase Ş
Local $key_G = Chr(0xF0) ;lowercase ğ
Local $key_I = Chr(0xFD) ;lowercase ı
Local $key_S = Chr(0xFE) ;lowercase ş

Local $string = "ĞİŞğış"
$string = StringRegExpReplace($string, "Ğ", "G")
$string = StringRegExpReplace($string, "İ", "I")
$string = StringRegExpReplace($string, "Ş", "S")
$string = StringRegExpReplace($string, "ğ", "g")
$string = StringRegExpReplace($string, "ı", "i")
$string = StringRegExpReplace($string, "ş", "s")
Local $result = ConsoleWrite($string) ;GISgis

Hello guys,

I need to rewrite some Turkish letters and I use these codes to do so.

How can I do these 6 commands with a single command?

Edited November 5, 2021 by mixim

[ViciousXUSMC]

I am sure there is a way to do this with pure regex using StringRegExpReplace() however since the matches are simple enough my thought process is to use a function that contains all your corresponding matches and replacements in an array or map or something and just use StringReplace()

 

Also you can try nesting functions.

 

$sString = "+h!s is @ test"

$sNewString = StringReplace(StringReplace(StringReplace($sString, "+", "t"), "!", "i"), "@", "a")

MsgBox(0, "", $sNewString)

 

Edited November 5, 2021 by ViciousXUSMC

[JockoDundee]

  On 11/5/2021 at 4:31 PM, mixim said:

How can I do these 6 commands in a single command?

Expand  

Well, if you insist:

$string=StringRegExpReplace(StringRegExpReplace(StringRegExpReplace(StringRegExpReplace(StringRegExpReplace(StringRegExpReplace($string, "Ğ", "G"), "İ", "I"), "Ş", "S"), "ğ", "g"), "ı", "i"),"ş", "s")

*not tested

[mixim]

  On 11/5/2021 at 4:46 PM, ViciousXUSMC said:

I am sure there is a way to do this with pure regex using StringRegExpReplace() however since the matches are simple enough my thought process is to use a function that contains all your corresponding matches and replacements in an array or map or something and just use StringReplace()

 

Expand  

Actually I am wondering if I could do it with pattern definition.

[mixim]

  On 11/5/2021 at 4:47 PM, JockoDundee said:

Well, if you insist:

$string=StringRegExpReplace(StringRegExpReplace(StringRegExpReplace(StringRegExpReplace(StringRegExpReplace(StringRegExpReplace($string, "Ğ", "G"), "İ", "I"), "Ş", "S"), "ğ", "g"), "ı", "i"),"ş", "s")

*not tested

Expand  

This is a good idea, thanks. I will do it is a last resort.

[ViciousXUSMC]

Same as I posted except no need for RegEx just StringReplace will suffice.

The main rule of RegEx is only use RegEx when its needed

[JockoDundee]

  On 11/5/2021 at 5:37 PM, ViciousXUSMC said:

The main rule of RegEx is only use RegEx when its needed

Expand  

The main rule of typing on an IPad while in the shower is “cut and paste”

[mixim]

Local $string = "ğĞçÇşŞüÜöÖıİ"
Local $a[12][12] = [[ "ğ", "Ğ", "ç", "Ç", "ş", "Ş", "ü", "Ü", "ö", "Ö", "ı", "İ" ], _
                    [ "g", "G", "c", "C", "s", "S", "u", "U", "o", "O", "i", "I" ]]
For $i = 0 To 11
    $string = StringReplace($string, $a[0][$i], $a[1][$i], 0, 1)
Next
Local $result = ConsoleWrite($string) ;gGcCsSuUoOiI

I made that for now, I guess I'll go with it this way.😖

Thank you so much for your helping.

Edited November 5, 2021 by mixim

[jchd]

Here's how to remove diacritics from accented letters in a Unicode string using a single regex replacement:

; Unicode Normalization Forms
Global Enum $UNF_NormC = 1, $UNF_NormD, $UNF_NormKC = 5, $UNF_NormKD

Func _Unaccent($s, $iMode = 0)
    Local Static $aPat = [ _
            "(*UCP)[\x{300}-\x{36F}`'¨^¸¯]", _    ; $iMode = 0 : remove combining accents only
            "(*UCP)\p{Mn}|\p{Lm}|\p{Sk}" _        ; $iMode = 1 :     "       "       "    and modifying letters
            ]
    Return StringRegExpReplace(_UNF_Change($s, $UNF_NormD), $aPat[Mod($iMode, 2)], "")
EndFunc   ;==>_Unaccent

; change UNF (Unicode Normalization Form)
Func _UNF_Change($sIn, $iForm)
    If $iForm = $UNF_NormC Or $iForm = $UNF_NormD Or $iForm = $UNF_NormKC Or $iForm = $UNF_NormKD Then
        Local $aRet = DllCall("Normaliz.dll", "int", "NormalizeString", "int", $iForm, "wstr", $sIn, "int", -1, "ptr", 0, "int", 0)
        Local $tOut = DllStructCreate("wchar[" & 2 * ($aRet[0] + 20) & "]")
        $aRet = DllCall("Normaliz.dll", "int", "NormalizeString", "int", $iForm, "wstr", $sIn, "int", -1, "ptr", DllStructGetPtr($tOut, 1), "int", 2 * ($aRet[0] + 20))
        Return DllStructGetData($tOut, 1)
    Else
        SetError(1, 0, $sIn)
    EndIf
EndFunc   ;==>_UNF_Change

However Turkish dotless "i" is not an accented letter and needs to be dealt with explicitely. So:

Local $s = "ğĞçÇşŞüÜöÖıİ  ЁЃЌЍӁ" ; also works for other scripts like cyrillic, etc.
Local $sUnTurkished = _Unaccent(StringReplace($s, "ı", "i"))

 

[mixim]

@jchd This had so great, now I can use this for all lang.
Thank you very very much, respects.

Edited November 7, 2021 by mixim