Is there a way of getting SciTe to show "Unmodified" in the title bar?

[c.haslam]

... when no changes have been made to an .au3 file? It would be nice

Edited April 21, 2024 by c.haslam

[Werty]

There is already a * when a script IS edited, isnt that good enough, if there's no * then it's not edited.

 

Edited April 21, 2024 by Werty

[Jos]

I see now several posts posts about SciTE, so like to remind you that i am using the standard SciTE and just made "some" autoit3 customisation. 

So the majority of SciTE is standard which i have no intention to further customise and like to redirect you to the official website for any requests for change in either the standard program or documentation.

[ioa747]

If you want it, it's easy to do
 

expandcollapse popup

; https://www.autoitscript.com/forum/topic/211822-is-there-a-way-of-getting-scite-to-show-unmodified-in-the-title-bar/?do=findComment&comment=1533078

#NoTrayIcon
#Region ;**** Directives created by AutoIt3Wrapper_GUI ****
#AutoIt3Wrapper_Outfile=Scite2Unmodified.exe
#AutoIt3Wrapper_Res_Comment=If there are command line arguments passed to the script, it sends them to SciTE.exe.
#AutoIt3Wrapper_Res_Description=If the SciTE title does not contain asterisks (*), appends "<Unmodified>" to the title and updates the window.
#AutoIt3Wrapper_Res_Fileversion=0.0.0.1
#AutoIt3Wrapper_Res_ProductName=Scite2Unmodified
#AutoIt3Wrapper_AU3Check_Parameters=-d -w 1 -w 2 -w 3 -w 4 -w 5 -w 6 -w 7
#EndRegion ;**** Directives created by AutoIt3Wrapper_GUI ****

#include <Misc.au3>

Global $sSciTE_exe = FileGetShortName("C:\Program Files (x86)\AutoIt3\SciTE\SciTE.exe") ; <<- modify if necessary ***

; If there are command line arguments passed to the script, it sends them to SciTE.exe.
If $CmdLine[0] > 0 Then
    For $i = 1 To $CmdLine[0]
        If FileExists($CmdLine[$i]) Then
            ; If the argument is a valid file path, execute SciTE.exe with that file as an argument
            ShellExecute($sSciTE_exe, $CmdLine[$i])
            Sleep(100)
        EndIf
    Next
EndIf

;You probably also want to test whether the script is already running to avoid running it multiple times!
If _Singleton("Scite2Unmodified", 1) = 0 Then Exit

WinWait("[CLASS:SciTEWindow]", "", 5)

If Not WinExists("[CLASS:SciTEWindow]") Then Exit

Global $sActiveTitle, $sCurTitle

While WinExists("[CLASS:SciTEWindow]")
    $sActiveTitle = WinGetTitle("[CLASS:SciTEWindow]")
    If $sCurTitle <> $sActiveTitle Then
        $sCurTitle = $sActiveTitle
        ; If the SciTE title does not contain asterisks (*), appends "<Unmodified>" to the title and updates the window.
        If Not StringInStr($sCurTitle, "*") Then
            $sCurTitle = "<Unmodified> " & $sCurTitle
            WinSetTitle("[CLASS:SciTEWindow]", "", $sCurTitle)
        EndIf
    EndIf

    Sleep(100)
WEnd

 

Edited April 22, 2024 by ioa747
add _Singleton

[c.haslam]

Thank you both. I didn't know about the *; now I do. I will stick with standard SciTe.