GUISetStyle(-1, $WS_POPUPWINDOW)

[ioa747]

Is the behavior of  _GUI2 logical ? 
Or is this just behaving strangely towards me?

expandcollapse popup

#include <GUIConstants.au3>

Global $Exit1, $Exit2

_GUI1()
_GUI2()

;**********************************
While True
    Switch GUIGetMsg()
        Case $GUI_EVENT_CLOSE, $Exit1, $Exit2
            Exit
    EndSwitch
WEnd
;**********************************

;----------------------------------------------------------------------------------------
Func _GUI1()
    Local $hGUI = GUICreate("Example Gui 1", 390, 320, @DesktopWidth * 0.7, -1, $WS_POPUPWINDOW)
;~  GUISetStyle(-1, $WS_POPUPWINDOW)
    GUISetBkColor(0x0D1117)

    Local $ShippingDetails = GUICtrlCreateLabel("Example Gui 1", 10, 5, 380, 30, -1, $GUI_WS_EX_PARENTDRAG)
    GUICtrlSetFont(-1, 18, 800, 0, "MS Sans Serif")
    GUICtrlSetColor(-1, 0xFFD800)

    $Exit1 = GUICtrlCreateButton("EXIT", 20, 270, 95, 40)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
    GUICtrlSetColor(-1, 0x0D1117)
    GUICtrlSetBkColor(-1, 0xFFD800)
    GUISetState(@SW_SHOW)

EndFunc   ;==>_GUI1
;----------------------------------------------------------------------------------------
Func _GUI2()
    Local $hGUI = GUICreate("Example Gui 2", 390, 320, @DesktopWidth * 0.3, -1)
    GUISetStyle(-1, $WS_POPUPWINDOW)
    GUISetBkColor(0x0D1117)

    Local $ShippingDetails = GUICtrlCreateLabel("Example Gui 2", 10, 5, 380, 30, -1, $GUI_WS_EX_PARENTDRAG)
    GUICtrlSetFont(-1, 18, 800, 0, "MS Sans Serif")
    GUICtrlSetColor(-1, 0xFFD800)

    $Exit2 = GUICtrlCreateButton("EXIT", 20, 270, 95, 40)
    GUICtrlSetFont(-1, 10, 800, 0, "MS Sans Serif")
    GUICtrlSetColor(-1, 0x0D1117)
    GUICtrlSetBkColor(-1, 0xFFD800)
    GUISetState(@SW_SHOW)

EndFunc   ;==>_GUI2

 

[argumentum]

..crazy, and I can't imagine the reason  

[pixelsearch]

What means -1 as 1st parameter of GuiSetStyle() ?

[argumentum]

Func _GUI2()
    Local $hGUI = GUICreate("Example Gui 2", 390, 320, @DesktopWidth * 0.3, -1)
    GUISetStyle($WS_POPUPWINDOW) ; <======

..you scared me there for a minute 😅

[argumentum]

According to Koda it should be GUISetStyle(BitOR($WS_SYSMENU,$WS_POPUP))

[pixelsearch]

Gui 1 (Control Viewer)
Style 0x94880000
WS_POPUP, WS_VISIBLE, WS_CLIPSIBLINGS, WS_BORDER, WS_SYSMENU

ExStyle 0

=================

For GUI2, the wrong syntax GUISetStyle(-1, $WS_POPUPWINDOW) messed up its ex style :

Gui 2 (GuiPropView)
Style 0x94CA0000 (unchanged, style kept as when GUI2 was created)

ExStyle 0x00080100 <= this is 0x80000 (WS_EX_LAYERED) that's why we couldn't see GUI2 + 0x100 (WS_EX_WINDOWEDGE)

 

Edited yesterday at 03:01 PM by pixelsearch
explanations

[pixelsearch]

From "GUIStyles.inc.au3"

[0x80880000, 'WS_POPUPWINDOW']

[0x80000000, 'WS_POPUP']
[0x00800000, 'WS_BORDER']
[0x00080000, 'WS_SYSMENU']

Great how these 8's are vertically aligned

[ioa747]

GUISetStyle ( Style [, ExStyle [, winhandle]] )

oops, my mind didn't go there.
first I did a reboot maybe ...
and then I started cursing Microsoft 

Thank you very much.