Dork Tower Slideshow

[james3mg]

If you know Dork Tower, you may enjoy having this up for a few days

expandcollapse popup

#Include <GUIConstants.au3>

$Paused=0
$SlideshowGUI=GUICreate("Dork Tower Slideshow by james3MG",450,700)
$TheComic=GUICtrlCreatePic("",0,0,450,600)
$BackButton=GUICtrlCreateButton("Back",5,675,100,20)
$Link=GUICtrlCreateLabel("",0,650,450,20,$SS_CENTER)
GUICtrlSetFont(-1,9,400,6)
GUICtrlSetColor(-1,0x0000FF)
GUICtrlSetCursor(-1,0)
$NextButton=GUICtrlCreateButton("Next",345,675,100,20)
Global $HistoryArray[1]=[0]
$SlideshowTimer=TimerInit()
NextSlide()
GUISetState()

While 1
    If TimerDiff($SlideshowTimer) > 120000 AND NOT $Paused Then
        NextSlide()
    EndIf
    Switch GUIGetMsg()
        Case 0
            ContinueLoop
        Case $BackButton
            If $HistoryArray[0] > 1 Then
                $HistoryArray[0]-=1
                INetGet("http://archive.gamespy.com/comics/dorktower/images/comics/dorktower"&$HistoryArray[$HistoryArray[0]]&".jpg",@TempDir&"\dorktower.jpg")
                GUICtrlSetData($Link,"http://archive.gamespy.com/comics/dorktower/images/comics/dorktower"&$HistoryArray[$HistoryArray[0]]&".jpg")
                GUICtrlSetImage($TheComic,@TempDir&"\dorktower.jpg")
                $Paused=1
            EndIf
        Case $NextButton
            NextSlide()
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Link
            Run(@ComSpec&' /c start "" "'&GUICtrlRead($Link)&'"',"",@SW_HIDE)
    EndSwitch
WEnd

Func NextSlide()
    $Paused=0
    $SlideshowTimer=TimerInit()
    If UBound($HistoryArray)=$HistoryArray[0]+1 Then
        ReDim $HistoryArray[UBound($HistoryArray)+1]
        $HistoryArray[0]+=1
        Do
            $HistoryArray[$HistoryArray[0]]=Random(1,2000,1)
        Until INetGet("http://archive.gamespy.com/comics/dorktower/images/comics/dorktower"&$HistoryArray[$HistoryArray[0]]&".jpg",@TempDir&"\dorktower.jpg")=1
    Else
        $HistoryArray[0]+=1
        INetGet("http://archive.gamespy.com/comics/dorktower/images/comics/dorktower"&$HistoryArray[$HistoryArray[0]]&".jpg",@TempDir&"\dorktower.jpg")
    EndIf
    GUICtrlSetData($Link,"http://archive.gamespy.com/comics/dorktower/images/comics/dorktower"&$HistoryArray[$HistoryArray[0]]&".jpg")
    GUICtrlSetImage($TheComic,@TempDir&"\dorktower.jpg")
EndFunc

It doesn't look great when he draws double-height comics sometimes (I don't feel like having the GUI size pop around based on the picture size just to fix this either), and I think he started mixing up the file names recently, so it doesn't get all the newest comics, but still...some of the old ones are the best anyway

...Now I just need one for Get Fuzzy. Darn comics.com and their random file names!

Edited July 26, 2007 by james3mg