unique lines only

[cdkid]

i'm trying to make a script that'll sort out only unique lines and for some reason i can't quite get it to work... this is what i have

$fil = "test.txt"
$fil = FileRead($fil)
$fil = StringSplit($fil, @CRLF)
dim $niqq = False
dim $niq[1]
for $i = 1 to $fil[0]
    $tempstr = $fil[$i]
    if $tempstr = "" Then
        ContinueLoop
    EndIf
    for $n = 0 to ubound($niq) - 1
        if $niqq = true Then
            $niqq = False
            ExitLoop
        EndIf
        if $tempstr = $niq[$n] Then
            ContinueLoop
        EndIf
        if $tempstr <> $niq[$n] Then
        redim $niq[ubound($niq)+1]
        $niq[Ubound($niq) - 1] = $tempstr
        $niqq = True
        EndIf
    Next
Next
for $i = 0 to ubound($niq) - 1
    if $niq[$i] <> "" Then
    filewrite("test22.txt", $niq[$i] & @CRLF)
EndIf

Next

the input file is

test
test
test
one
one
two
three

and the output comes out as

test
test
one
one
two
two
three
three

any help'd be much appreciated

~cdkid

[PsaltyDS]

i'm trying to make a script that'll sort out only unique lines and for some reason i can't quite get it to work... this is what i have

; ...

the input file is

test
test
test
one
one
two
three

This is not the fastest, but illustrates the basic loop (note it goes backwards thru the array deleting duplicates):

#include <array.au3>

$fil = "test.txt"
$fil = FileRead($fil)
$fil = StringSplit($fil, @CRLF)

For $i = $fil[0] To 1 Step - 1
    $tempstr = StringStripWS($fil[$i], 3)
    If $tempstr = "" Then
        _ArrayDelete($fil, $i)
    Else
        If $i = 1 Then ExitLoop
        For $n = $i - 1 To 1 Step - 1
            If $tempstr = $fil[$n] Then
                _ArrayDelete($fil, $i)
                ExitLoop
            EndIf
        Next
    EndIf
Next
$fil[0] = UBound($fil) - 1
_ArrayDisplay($fil, "Debug: $fil output")

If $fil[0] > 0 Then
    _FileWriteFromArray("test22.txt", $fil, 1)
Else
    MsgBox(16, "Error", "No results left.")
EndIf

If it's really all single words, then a scripting dictionary would be much faster. But the above code is nice and simple, if speed is not a big issue.

Edit: Typo.

Edited July 28, 2007 by PsaltyDS

[SmOke_N]

_FileReadToArray() + _ArrayUnique()

Should do it for you.

[cdkid]

thanks burt & smoke...

didn't know arrayunique existed

both of those worked

~cdkid